Conas aird a tharraingt ar théacs ar leith laistigh de chill bunaithe ar théacs eile?

In Excel, b’fhéidir go mbeadh sé éasca dúinn aird a tharraingt ar na cealla atá bunaithe ar théacs ar leith, ach, anseo, ba mhaith liom aird a tharraingt ar théacs ar leith laistigh de chill chun é a dhéanamh gan íoc ach ní an chill iomlán. B’fhéidir gur trioblóideach é seo don chuid is mó dínn. An t-alt seo, labhróidh mé faoi roinnt cleasanna chun an post seo a réiteach in Excel.

Aibhsigh téacs sonrach amháin nó níos mó laistigh de ilchealla le cód VBA

Aibhsigh téacs sonrach amháin nó níos mó laistigh de ilchealla a bhfuil gné iontach acu

Aibhsigh téacs sonrach laistigh de chill bunaithe ar théacs eile le cód VBA

Aibhsigh téacs sonrach amháin nó níos mó laistigh de ilchealla le cód VBA

Mar shampla, tá réimse teaghráin téacs agam, agus anois, ba mhaith liom aird a tharraingt ar an téacs sonrach “Sky”Sna cealla seo chun an toradh a fháil mar a thaispeántar na scáileáin scáileáin seo a leanas:

Chun ach cuid de théacs laistigh de chill a aibhsiú, is féidir leis an gcód VBA seo a leanas cabhrú leat.

1. Roghnaigh na cealla ar mhaith leat aird a tharraingt ar an téacs sonrach, agus ansin coinnigh síos an ALT + F11 eochracha a oscailt Microsoft Visual Basic d’Fheidhmchláir fhuinneog.

2. Cliceáil Ionsáigh > Modúil, agus greamaigh an cód seo a leanas sa Modúil Fuinneog.

Cód VBA: Aibhsigh cuid den téacs laistigh de chill:

Sub HighlightStrings()
'Updateby Extendoffice
Application.ScreenUpdating = False
Dim Rng As Range
Dim cFnd As String
Dim xTmp As String
Dim x As Long
Dim m As Long
Dim y As Long
cFnd = InputBox("Enter the text string to highlight")
y = Len(cFnd)
For Each Rng In Selection
  With Rng
    m = UBound(Split(Rng.Value, cFnd))
    If m > 0 Then
      xTmp = ""
      For x = 0 To m - 1
        xTmp = xTmp & Split(Rng.Value, cFnd)(x)
        .Characters(Start:=Len(xTmp) + 1, Length:=y).Font.ColorIndex = 3
        xTmp = xTmp & cFnd
      Next
    End If
  End With
Next Rng
Application.ScreenUpdating = True
End Sub

3. Ansin brúigh F5 eochair chun an cód seo a rith, agus tiocfaidh bosca pras amach le cur i gcuimhne duit an téacs nach dteastaíonn uait a aibhsiú ach amháin, féach an scáileán:

4. Agus ansin cliceáil OK cnaipe, aibhsíodh an téacs go léir a shonraigh tú laistigh de na cealla amháin, féach an scáileán:

Leideanna: Más gá duit eochairfhocail iolracha a aibhsiú ó na teaghráin téacs, cuir an cód thíos i bhfeidhm:
Cód VBA: Aibhsigh eochairfhocail iolracha ó teaghráin téacs:

Sub HighlightStrings()
'Updateby Extendoffice
Application.ScreenUpdating = False
Dim Rng As Range
Dim cFnd As String
Dim xTmp As String
Dim x As Long
Dim m As Long
Dim y As Long
Dim xFNum As Integer
Dim xArrFnd As Variant
Dim xStr As String
cFnd = InputBox("Please enter the text, separate them by comma:")
If Len(cFnd) < 1 Then Exit Sub
xArrFnd = Split(cFnd, ",")
For Each Rng In Selection
With Rng
For xFNum = 0 To UBound(xArrFnd)
xStr = xArrFnd(xFNum)
y = Len(xStr)
m = UBound(Split(Rng.Value, xStr))
If m > 0 Then
xTmp = ""
For x = 0 To m - 1
xTmp = xTmp & Split(Rng.Value, xStr)(x)
.Characters(Start:=Len(xTmp) + 1, Length:=y).Font.ColorIndex = 3
xTmp = xTmp & xStr
Next
End If
Next xFNum
End With
Next Rng
Application.ScreenUpdating = True
End Sub

Ansin, sa bhosca popped out, cuir isteach na heochairfhocail ar mhaith leat aird a tharraingt orthu, (déan na focail a scaradh le camóg), féach an scáileán:

Agus ansin, cliceáil OK cnaipe, aibhsíodh na focail shonraithe ag an am céanna, féach screenshots:

nótaí: Tá na cóid thuas cás-íogair.

Aibhsigh téacs sonrach amháin nó níos mó laistigh de ilchealla a bhfuil gné iontach acu

Mura bhfuil tú eolach ar an gcód in Excel, anseo, tabharfaidh mé uirlis éasca isteach - Kutools for Excel, Lena Marcáil Eochairfhocal gné, is féidir leat aird a tharraingt ar an eochairfhocal sonrach amháin nó níos mó ag an am céanna laistigh de na cealla.

Tar éis a shuiteáil Kutools for Excel, déan mar a leanas le do thoil:

1. Cliceáil Kutools > Téacs > Marcáil Eochairfhocal, féach ar an scáileán:

2. Sa an Marcáil Eochairfhocal bosca dialóige, déan na hoibríochtaí seo a leanas le do thoil:

• Roghnaigh an raon sonraí a theastaíonn uait a úsáid as an Raon Bosca téacs;
• Roghnaigh na cealla tá na heochairfhocail ar mhaith leat aird a tharraingt orthu, is féidir leat na heochairfhocail a iontráil de láimh (ar leithligh le camóg) sa Eochairfhocal Bosca téacs
• Faoi dheireadh, ba cheart duit clómhéid a shonrú chun aird a tharraingt ar na téacsanna le seic Marcáil dathanna eochairfhocal rogha. (Chun na cealla iomlána ina bhfuil na heochairfhocail a dhathú, roghnaigh an Marcáil na dathanna ábhar cille rogha)

3. Ansin, cliceáil Ok cnaipe, aibhsíodh gach téacs sonraithe mar atá thíos an pictiúr a thaispeántar:

nótaí: Níl an ghné seo cás-íogair, más mian leat aird a tharraingt ar an téacs le cás-íogair, seiceáil le do thoil Meaitseáil Cás sa Marcáil Eochairfhocal dialóg.

Aibhsigh téacs sonrach laistigh de chill bunaithe ar théacs eile le cód VBA

Seo cás eile, tá dhá cholún agam ina bhfuil na teaghráin téacs sa chéad cholún agus is é an dara colún an téacs sonrach, anois, ní mór dom aird a tharraingt ar an téacs coibhneasta sa chéad cholún bunaithe ar an téacs sonrach sa dara colún do gach ceann as a chéile.

1. Coinnigh síos an ALT + F11 eochracha a oscailt Microsoft Visual Basic d’Fheidhmchláir fhuinneog.

2. Cliceáil Ionsáigh > Modúil, agus greamaigh an cód seo a leanas sa Modúil Fuinneog.

Cód VBA: Aibhsigh cuid de théacs laistigh de chill bunaithe ar théacs eile:

Sub highlight()
'Updateby Extendoffice
    Dim xStr As String
    Dim xRg As Range
    Dim xTxt As String
    Dim xCell As Range
    Dim xChar As String
    Dim I As Long
    Dim J As Long
    On Error Resume Next
    If ActiveWindow.RangeSelection.Count > 1 Then
      xTxt = ActiveWindow.RangeSelection.AddressLocal
    Else
      xTxt = ActiveSheet.UsedRange.AddressLocal
    End If
LInput:
    Set xRg = Application.InputBox("please select the data range:", "Kutools for Excel", xTxt, , , , , 8)
    If xRg Is Nothing Then Exit Sub
    If xRg.Areas.Count > 1 Then
        MsgBox "not support multiple columns"
        GoTo LInput
    End If
    If xRg.Columns.Count <> 2 Then
        MsgBox "the selected range can only contain two columns "
        GoTo LInput
    End If
    For I = 0 To xRg.Rows.Count - 1
        xStr = xRg.Range("B1").Offset(I, 0).Value
        With xRg.Range("A1").Offset(I, 0)
            .Font.ColorIndex = 1
            For J = 1 To Len(.Text)
                If Mid(.Text, J, Len(xStr)) = xStr Then .Characters(J, Len(xStr)).Font.ColorIndex = 3
            Next
        End With
    Next I
End Sub

3. Tar éis an cód a ghreamú, agus brúigh F5 eochair chun é a rith, tiocfaidh bosca pras amach le cur i gcuimhne duit an raon sonraí a roghnú ina bhfuil an sreangán téacs agus an téacs sonrach ar mhaith leat aird a tharraingt air agus bunaithe air, féach an scáileán:

4. Agus ansin cliceáil OK cnaipe, tá an téacs comhfhreagrach uile sa chéad cholún bunaithe ar an téacs sonrach sa dara colún daite dearg mar a leanas:

Earraí níos coibhneasta: