Conas il macraí a reáchtáil ón roghchlár cliceáil ar dheis in Excel?

Má tá macraí vba iolracha i do leabhar oibre, ba cheart duit an fhuinneog VBA a oscailt agus ansin an macra a roghnú nuair is gá duit an cód a rith. San Airteagal seo, ba mhaith liom labhairt faoi conas macraí a rith ón roghchlár cliceáil ar dheis chun do chuid oibre a dhéanamh níos éifeachtaí mar a thaispeántar an scáileán clé.

Rith macraí iolracha ón roghchlár cliceáil ar dheis le cóid VBA

Rith macraí iolracha ón roghchlár cliceáil ar dheis le cóid VBA

Chun na cóid macra laistigh de leabhar oibre a rith ón roghchlár cliceáil ar dheis, d'fhéadfadh na céimeanna seo a leanas cabhrú leat, déan mar seo le do thoil:

1. Poll síos an Alt + F11 eochracha a oscailt Microsoft Visual Basic d’Fheidhmchláir fhuinneog.

2. Ansin, cliceáil faoi dhó An Leabhar Oibre seo ar chlé tionscadal pane, agus ansin cóipeáil agus greamaigh an cód VBA thíos isteach sa mhodúl bán.

Private Sub Workbook_Open()
Run "LoadMacro"
End Sub
Private Sub Workbook_Activate()
Run "LoadMacro"
End Sub
Private Sub Workbook_Deactivate()
Run "ClearMacro"
End Sub
Private Sub Workbook_BeforeClose(Cancel As Boolean)
Run "ClearMacro"
ThisWorkbook.Save
End Sub

3. Fós sa Microsoft Visual Basic d’Fheidhmchláir fuinneog, cliceáil le do thoil Ionsáigh > Modúil, agus greamaigh an cód seo a leanas isteach sa mhodúl seo.

Private Sub LoadMacro()
Dim xArrMenu As Variant
Dim xStrLine, xSreBtnName As String
Dim xObjCBCF, xObjCntrAll As CommandBarControl
Dim xObjCBCs As CommandBars
Dim xObjCBBtn As CommandBarButton
Dim xIntLine, xFNum As Integer
Dim xObjComponent As Object
Run "ClearMacro"
Set xObjCBCF = Application.CommandBars("Cell").Controls.Add(msoControlPopup, before:=1)
xObjCBCF.Caption = " Run Macro "
xObjCBCF.BeginGroup = False
For Each xObjComponent In ActiveWorkbook.VBProject.VBComponents
    If xObjComponent.Type = 1 Then
        For xIntLine = 1 To xObjComponent.CodeModule.CountOfLines
        xStrLine = xObjComponent.CodeModule.Lines(xIntLine, 1)
        xStrLine = Trim(xStrLine)
            If (InStr(xStrLine, "()") > 0) And (Left(xStrLine, 11) = "Private Sub" Or Left(xStrLine, 3) = "Sub") Then
            xSreBtnName = ""
            If "Private Sub" = Left(xStrLine, 11) Then
                xSreBtnName = Trim(Mid(xStrLine, 12, InStr(xStrLine, "()") - 12))
            ElseIf "Sub" = Left(xStrLine, 3) Then
               xSreBtnName = Trim(Mid(xStrLine, 4, InStr(xStrLine, "()") - 4))
            End If
            If xSreBtnName <> "" And xSreBtnName <> "RightClickReset" And xSreBtnName <> "LoadMacro" And xSreBtnName <> "ActionMacro" Then
                Set xObjCBBtn = xObjCBCF.Controls.Add
                With xObjCBBtn
                    .FaceId = 186
                    .Style = msoButtonIconAndCaption
                    .Caption = xSreBtnName
                    .OnAction = "ActionMacro"
                End With
            End If
            End If
        Next xIntLine
    End If
Next xObjComponent
End Sub
Private Sub ClearMacro()
On Error Resume Next
CommandBars("Cell").Controls(" Run Macro ").Delete
Err.Clear
CommandBars("Cell").Reset
End Sub
Private Sub ActionMacro()
On Error GoTo Err1
With Application
Run .CommandBars("Cell").Controls(1).Controls(.Caller(1)).Caption
End With
Exit Sub
Err1:
    MsgBox "Invalid"
End Sub

4. Tar éis na cóid a ghreamú, ansin cliceáil uirlisí > tagairtí, Agus Tagairtí-VBAProject Tá bosca dialóige ar taispeáint, agus ansin seiceáil Microsoft Visual Basic d'Iarracht Feidhmchlár 5.3 rogha sa Tagairtí atá ar Fáil bosca liosta, féach an scáileán:

5. Ansin cliceáil OK chun an dialóg a fhágáil, anois, ba cheart duit an leabhar oibre seo a shábháil mar Leabhar Oibre Macra-Chumasaithe Excel formáid, féach an scáileán:

6. Ar deireadh, atosaigh an leabhar oibre le do thoil chun éifeacht na gcód a ghlacadh, agus anois, nuair a chliceálann tú cill ar dheis, a Rith Macra Cuirtear an rogha isteach sa roghchlár cliceáil ar dheis, agus tá gach macraí i do leabhar oibre liostaithe san fho-roghchlár mar an seat seo a leanas:

7. Ansin is féidir leat an cód a rith ach cliceáil air.