Lean na céimeanna thíos chun struchtúr fillteán Outlook a chóipeáil chuig an taiscéalaí deisce nó fuinneoga.

1. Ar an bPána Nascleanúna, cliceáil le do thoil chun aird a tharraingt ar an bhfillteán sonraithe a ndéanfaidh tú struchtúr a fhillteáin a chóipeáil, agus brúigh Eile + F11 eochracha chun an fhuinneog Microsoft Visual Basic for Applications a oscailt.

2. cliceáil uirlisí > tagairtí chun an bosca dialóige Tagairtí a oscailt. Ansin sa bhosca dialóige seiceáil an Microsoft Scripting Runtime rogha, agus cliceáil ar an OK cnaipe. Féach an pictiúr:

3. cliceáil Ionsáigh > Modúil, agus cóipeáil agus greamaigh faoi bhun chód VBA isteach i bhfuinneog an mhodúil nua.

VBA: Cóipeáil struchtúr fillteán Outlook chuig taiscéalaí fuinneoga

Dim xFSO As Scripting.FileSystemObject
Sub CopyOutlookFldStructureToWinExplorer()
    ExportAction "Copy"
End Sub
  
Sub ExportAction(xAction As String)
Dim xFolder As Outlook.Folder
Dim xFldPath As String
xFldPath = SelectAFolder()
If xFldPath = "" Then
    MsgBox "You did not select a folder. Export cancelled.", vbInformation + vbOKOnly, "Kutools for Outlook"
Else
    Set xFSO = New Scripting.FileSystemObject
    Set xFolder = Outlook.Application.ActiveExplorer.CurrentFolder
    ExportOutlookFolder xFolder, xFldPath
End If
Set xFolder = Nothing
Set xFSO = Nothing
End Sub

Sub ExportOutlookFolder(ByVal OutlookFolder As Outlook.Folder, xFldPath As String)
Dim xSubFld As Outlook.Folder
Dim xItem As Object
Dim xPath As String
Dim xFilePath As String
Dim xSubject As String
Dim xCount As Integer
Dim xFilename As String
On Error Resume Next
xPath = xFldPath & "\" & OutlookFolder.Name
'?????????,??????
If Dir(xPath, 16) = Empty Then MkDir xPath
For Each xItem In OutlookFolder.Items
    xSubject = ReplaceInvalidCharacters(xItem.Subject)
    xFilename = xSubject & ".msg"
    xCount = 0
    xFilePath = xPath & "\" & xFilename
    If xFSO.FileExists(xFilePath) Then
        xCount = xCount + 1
        xFilename = xSubject & " (" & xCount & ").msg"
        xFilePath = xPath & "\" & xFilename
    End If
    xItem.SaveAs xFilePath, olMSG
Next
For Each xSubFld In OutlookFolder.Folders
    ExportOutlookFolder xSubFld, xPath
Next
Set OutlookFolder = Nothing
Set xItem = Nothing
End Sub

Function SelectAFolder() As String
Dim xSelFolder As Object
Dim xShell As Object
On Error Resume Next
Set xShell = CreateObject("Shell.Application")
Set xSelFolder = xShell.BrowseForFolder(0, "Select a folder", 0, 0)
If Not TypeName(xSelFolder) = "Nothing" Then
    SelectAFolder = xSelFolder.self.Path
End If
Set xSelFolder = Nothing
Set xShell = Nothing
End Function
  
Function ReplaceInvalidCharacters(Str As String) As String
Dim xRegEx
Set xRegEx = CreateObject("vbscript.regexp")
xRegEx.Global = True
xRegEx.IgnoreCase = False
xRegEx.Pattern = "\||\/|\<|\>|""|:|\*|\\|\?"
ReplaceInvalidCharacters = xRegEx.Replace(Str, "")
End Function

4. Brúigh F5 eochair nó cliceáil ar an Rith cnaipe chun an VBA seo a rith.

5. Sa bhosca dialóige Brabhsáil Chun Fillteán, roghnaigh an fillteán sonraithe cuirfidh tú struchtúr an fhillteáin chóipeáilte, agus cliceáil ar an OK cnaipe. Féach an pictiúr:

Anois téigh go dtí an fillteán sonraithe, feicfidh tú go ndéantar struchtúr an fhillteáin a chóipeáil chuig an diosca crua sonraithe. Féach an pictiúr:

nótaí: cóipeáiltear míreanna an fhillteáin, mar ríomhphoist, coinní, tascanna, srl. i bhfillteáin chomhfhreagracha sa diosca crua.

Conas struchtúr an fhillteáin a chóipeáil chuig comhad sonraí pst nua in Outlook?