Conas tascanna a phriontáil bunaithe ar chatagóir in Outlook?

Ag ceapadh, tá catagóirí dathanna éagsúla i do thascanna Outlook, agus anois, ba mhaith leat liostaí na dtascanna a phriontáil bunaithe ar na catagóirí ar leathanaigh éagsúla. Conas a d’fhéadfá an post seo a réiteach in Outlook?

Priontáil tascanna bunaithe ar chatagóirí ar leathanaigh éagsúla de láimh ceann ar cheann

Priontáil tascanna bunaithe ar chatagóirí ar leathanaigh éagsúla le cód VBA

Priontáil tascanna bunaithe ar chatagóirí ar leathanaigh éagsúla de láimh ceann ar cheann

In Outlook, is féidir leat na tascanna a phriontáil de láimh bunaithe ar na catagóirí éagsúla ar leathanaigh éagsúla ceann ar cheann, déan mar seo le do thoil:

1. Seoladh an Outlook, agus téigh go dtí an phána Tasc agus roghnaigh an fillteán tascanna a theastaíonn uait a phriontáil, agus ansin brúigh Ctrl + E a ghníomhachtú an Cuardaigh bosca, agus ansin faoin Cuardaigh tab, cliceáil Catagóirithe íocón, agus roghnaigh catagóir dathanna amháin a chaithfidh tú a phriontáil, féach an scáileán:

tascanna priontála doc de réir catagóire 1

2. Agus ansin, liostaítear na tascanna go léir leis an gcatagóir dathanna ar leith ag an am céanna, féach an scáileán:

tascanna priontála doc de réir catagóire 2

3. Ansin, téigh ar cliceáil Comhad > Print chun an liosta tascanna seo a phriontáil mar a leanas an pictiúr a thaispeántar:

tascanna priontála doc de réir catagóire 3

4. Déan na céimeanna thuas arís chun liostaí na dtascanna a phriontáil amach leis na catagóirí dathanna eile ceann ar cheann de láimh.

Priontáil tascanna bunaithe ar chatagóirí ar leathanaigh éagsúla le cód VBA

Seo cód VBA a chabhróidh leat na tascanna atá bunaithe ar an gcatagóir a phriontáil ar leathanaigh éagsúla ag an am céanna, déan na céimeanna seo a leanas le do thoil:

1. Téigh go dtí an Tasc pána agus roghnaigh an fillteán tascanna a theastaíonn uait a phriontáil.

2. Ansin, coinnigh síos an ALT + F11 eochracha a oscailt Microsoft Visual Basic d’Fheidhmchláir fhuinneog.

3. Agus ansin, cliceáil Ionsáigh > Modúil, cóipeáil agus greamaigh an cód thíos sa mhodúl bán oscailte:

Cód VBA: Priontáil tascanna bunaithe ar chatagóirí ar leathanaigh éagsúla:

Sub PrintTaskList_SpecificColorCategory()
    Dim xTaskItems As Outlook.Items
    Dim xTask As Outlook.TaskItem
    Dim xDictionary As Scripting.Dictionary
    Dim xCategoryArr As Variant, xCategory As Variant
    Dim xExcelApp As Excel.Application
    Dim xExcelWorkbook As Excel.Workbook
    Dim xExcelWorksheet As Excel.Worksheet
    Dim xSheet As Excel.Worksheet
    Dim xKey As Variant
    Dim xKeyStr As String
    Dim i As Long, xLastRow As Integer
    On Error Resume Next
    If Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olTaskItem Then Exit Sub
    Set xTaskItems = Application.ActiveExplorer.CurrentFolder.Items
    Set xDictionary = New Scripting.Dictionary
    For Each xTask In xTaskItems
        xCategoryArr = Split(xTask.Categories, ",")
        For Each xCategory In xCategoryArr
            If xDictionary.Exists(Trim(xCategory)) = False Then
               xDictionary.Add Trim(xCategory), 0
            End If
        Next
    Next
    If xDictionary.Count = 0 Then
        MsgBox "The current Task doesn’t have any category", vbOKOnly + vbInformation, "Kutools for Outlook"
        Exit Sub
    End If
    Set xExcelApp = New Excel.Application
    Set xExcelWorkbook = xExcelApp.Workbooks.Add
    xExcelApp.Visible = True
    i = 0
    If xDictionary.Count > xExcelWorkbook.Sheets.Count Then
        xExcelWorkbook.Sheets.Add Count:=xDictionary.Count - xExcelWorkbook.Sheets.Count
    End If
    For Each xKey In xDictionary.Keys
        xKeyStr = CStr(xKey)
        i = i + 1
        Set xExcelWorksheet = xExcelWorkbook.Sheets(i)
        xExcelWorksheet.Name = xKeyStr
        With xExcelWorksheet
             .Range("A1") = xKeyStr
             .Range("A1").Font.Bold = True
             .Range("A1").Font.Size = 18
             .Range("A1", "C1").HorizontalAlignment = xlCenter
             .Range("A1", "C1").VerticalAlignment = xlCenter
             .Range("A1", "C1").Merge
             .Range("A2") = "Subject"
             .Range("A2").Font.Bold = True
             .Range("B2") = "Start Date"
             .Range("B2").Font.Bold = True
             .Range("C2") = "Due Date"
             .Range("C2").Font.Bold = True
        End With
        For Each xTask In xTaskItems
            If InStr(xTask.Categories, xKeyStr) > 0 Then
               xLastRow = xExcelWorksheet.UsedRange.Rows.Count + 1
               With xExcelWorksheet
                    .Range("A" & xLastRow) = xTask.Subject
                    .Range("B" & xLastRow) = xTask.StartDate
                    .Range("C" & xLastRow) = xTask.DueDate
               End With
            End If
        Next
        xExcelWorksheet.Columns("A:C").AutoFit
    Next
    For Each xSheet In xExcelWorkbook.Sheets
        xSheet.PrintOut
    Next
    xExcelWorkbook.Close False
    xExcelApp.Quit
End Sub

4. Ansin cliceáil uirlisí > tagairtí sa Microsoft Visual Basic d’Fheidhmchláir fhuinneog, sa popped amach Tagairtí-Tionscadal1 bosca dialóige, seiceáil Leabharlann Réada Microsoft Excel agus Microsoft Scripting Runtime roghanna ón Tagairtí atá ar Fáil bosca liosta, féach an scáileán:

tascanna priontála doc de réir catagóire 4

5. Agus ansin, cliceáil OK cnaipe, anois, brúigh F5 eochair chun an cód seo a rith, tar éis duit an cód a chríochnú, priontálfar liostaí na dtascanna le catagóirí éagsúla ar leathanaigh éagsúla.