Conas freagra a thabhairt de ghnáth i bhfillteán earraí seolta ó Outlook? 

De ghnáth, nuair a chliceálann tú Freagra gné i bhfillteán míreanna Seolta chun teachtaireacht bhreise eile a sheoladh chuig na daoine a sheol tú, taispeánfar do sheoladh ríomhphoist féin ag an réimse To mar a thaispeántar ar an scáileán a leanas. D’fhéadfadh sé seo a bheith buartha duit an seoladh a athrú gach uair. Conas a d’fhéadfadh an Outlook seoladh an fhaighteora bhunaidh a úsáid, ní mise?

Freagra de ghnáth i bhfillteán Míreanna Seolta ó Outlook le gné Reply All

Freagra de ghnáth i bhfillteán Míreanna Seolta ó Outlook le cód VBA

---

Freagra de ghnáth i bhfillteán Míreanna Seolta ó Outlook le gné Reply All

In Outlook, tá an Freagra Gach is féidir le gné cabhrú leat an fhadhb seo a réiteach, déan mar seo le do thoil:

Nuair is gá duit an ríomhphost seolta a fhreagairt lena sheoladh arís chun seoladh an fhaighteora bhunaidh a choinneáil, cliceáil le do thoil Freagra Gach cnaipe, agus tá seoladh an fhaighteora bhunaidh suite ag an Chun réimse mar a thaispeántar an pictiúr seo a leanas:

---

Freagra de ghnáth i bhfillteán Míreanna Seolta ó Outlook le cód VBA

Am éigin, féadfaidh tú dearmad a dhéanamh ar an Freagra Gach gné agus an teachtaireacht seolta á freagairt agat, mar sin is féidir leis an gcód VBA thíos cabhrú leat freagra a thabhairt de ghnáth i bhfillteán Míreanna Seolta tríd an ngné Freagra a úsáid. Déan na céimeanna seo a leanas:

1. Coinnigh síos an ALT + F11 eochracha a oscailt Microsoft Visual Basic d’Fheidhmchláir fhuinneog.

2. Sa an Microsoft Visual Basic d’Fheidhmchláir fuinneog, cliceáil dúbailte ThisOutlookSession ó na Tionscadal1 (VbaProject.OTM) pána chun an modh a oscailt, agus ansin an cód seo a leanas a chóipeáil agus a ghreamú isteach sa mhodúl bán.

Cód VBA: Freagra de ghnáth i bhfillteán Míreanna Seolta ó Outlook:

Option Explicit
Private WithEvents GExplorer As Explorer
Private WithEvents GMailItem As MailItem
Private Sub Application_Startup()
    Set GExplorer = Application.ActiveExplorer
End Sub
Private Sub GExplorer_SelectionChange()
   On Error Resume Next
   Set GMailItem = GExplorer.Selection.Item(1)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
Dim xResponse As MailItem
Dim xRecipients As Outlook.Recipients
Dim xRecipient As Outlook.Recipient
Dim i As Integer
Dim xTo As String, xCC As String, xBCC As String, xName As String
On Error Resume Next
If Application.ActiveExplorer.CurrentFolder <> Session.GetDefaultFolder(olFolderSentMail) Then
    Exit Sub
End If
Cancel = True
Set xResponse = GMailItem.Reply
Set xRecipients = GMailItem.Recipients
For i = xRecipients.Count To 1 Step -1
    Set xRecipient = xRecipients.Item(i)
    xName = xRecipient.Name
    If Left(xName, 1) = "'" Then
        xName = Mid(xName, 2, Len(xRecipient.Name) - 2)
    End If
    Select Case xRecipient.Type
        Case olTo
            xTo = xName & ";" & xTo
        Case olCC
            xCC = xName & ";" & xCC
        Case olBCC
            xBCC = xName & ";" & xBCC
    End Select
Next
With xResponse
    .To = xTo
    .CC = xCC
    .BCC = xBCC
End With
xResponse.Recipients.ResolveAll
xResponse.Display
End Sub

3. Ansin, sábháil an cód, agus déan an Outlook a atosú chun éifeacht an chóid a ghlacadh, anois, agus tú ag cliceáil Freagra chun ríomhphost a athsheoladh i Míreanna Seolta fillteán, taispeántar seoladh an fhaighteora bhunaidh ag an réimse To mar is gá duit.