Conas an chatagóir a choinneáil agus tú ag freagairt nó ag seoladh ríomhphoist in Outlook? 

De ghnáth, nuair a thugann tú freagra nó ríomhphost ar aghaidh a rinne mé a chatagóiriú, bainfear an chatagóir go huathoibríoch ar an ríomhphost seolta. Más mian leat an chatagóir ar ríomhphoist atá ag dul as oifig a choinneáil ag freagairt nó ag cur ar aghaidh, tabharfaidh an t-alt seo modh isteach chun déileáil leis.

Coinnigh an chatagóir agus tú ag freagairt nó ag seoladh ríomhphoist le cód VBA

Coinnigh an chatagóir agus tú ag freagairt nó ag seoladh ríomhphoist le cód VBA

1. Coinnigh síos an ALT + F11 eochracha a oscailt Microsoft Visual Basic d’Fheidhmchláir fhuinneog.

2. Sa an Microsoft Visual Basic d’Fheidhmchláir fuinneog, cliceáil dúbailte ThisOutlookSession ó na Tionscadal1 (VbaProject.OTM) pána chun an modh a oscailt, agus ansin an cód seo a leanas a chóipeáil agus a ghreamú isteach sa mhodúl bán.

Cód VBA: Coinnigh an chatagóir agus tú ag freagairt nó ag seoladh ríomhphoist:

Private WithEvents GExplorer As Outlook.Explorer
Private WithEvents GInspectors As Outlook.Inspectors
Private WithEvents GMailItem As Outlook.MailItem
Private GCategories As String
Private Sub Application_Startup()
    Dim xApp As Outlook.Application
    Set xApp = Outlook.Application
    Set GExplorer = xApp.ActiveExplorer
    Set GInspectors = xApp.Inspectors
End Sub
Private Sub GExplorer_SelectionChange()
    On Error Resume Next
    If TypeName(GExplorer.Selection.Item(1)) <> "MailItem" Then Exit Sub
    Set GMailItem = GExplorer.Selection.Item(1)
    GCategories = GMailItem.Categories
End Sub
Private Sub GInspectors_NewInspector(ByVal Inspector As Inspector)
    On Error Resume Next
    If TypeName(Inspector.CurrentItem) <> "MailItem" Then Exit Sub
   Set GMailItem = Inspector.CurrentItem
    GCategories = GMailItem.Categories
End Sub
Private Sub GMailItem_Forward(ByVal Forward As Object, Cancel As Boolean)
    Call GetCategories(Forward)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GMailItem_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GetCategories(ByVal NewMail As Object)
    If NewMail.Class <> olMail Then Exit Sub
    NewMail.Categories = GCategories
End Sub

3. Ansin sábháil agus dún an fhuinneog cód seo, dún agus atosaigh an Outlook, anois, nuair a thabharfaidh tú freagra nó seol ríomhphost ar aghaidh le catagóir, coimeádfar an chatagóir sa teachtaireacht atá ag dul as oifig i Míreanna Seolta, féach ar an scáileán: