In ionad doiciméad a roinnt ina iliomad doiciméad de láimh, tabharfaidh an modh seo VBA isteach chun doiciméad Word a roinnt ar an teimpléad sonraithe i Word. Déan mar a leanas le do thoil:

1. Brúigh Alt + F11 eochracha le chéile chun an fhuinneog Microsoft Visual Basic for Application a oscailt;

2. Cliceáil Ionsáigh > Modúil, agus ansin greamaigh faoi bhun chód VBA isteach i bhfuinneog nua an Mhodúil oscailte.

VBA: Roinn Doiciméad Focal i nDoiciméid Il le Delimiter

Sub SplitNotes(delim As String, strFilename As String)
Dim doc As Document
Dim arrNotes
Dim I As Long
Dim X As Long
Dim Response As Integer
arrNotes = Split(ActiveDocument.Range, delim)
Response = MsgBox("This will split the document into " & UBound(arrNotes) + 1 & " sections.Do you wish to proceed?", 4)
If Response = 7 Then Exit Sub
For I = LBound(arrNotes) To UBound(arrNotes)
If Trim(arrNotes(I)) <> "" Then
X = X + 1
Set doc = Documents.Add
doc.Range = arrNotes(I)
doc.SaveAs ThisDocument.Path & "\" & strFilename & Format(X, "000")
doc.Close True
End If
Next I
End Sub
Sub test()
'delimiter & filename
SplitNotes "///", "Notes "
End Sub

3. Ansin cliceáil Rith cnaipe nó brúigh eochair F5 chun an VBA a chur i bhfeidhm.

4. Sa doiciméad Microsoft Word a phiocadh amach, cliceáil le do thoil an cnaipe Sea chun dul ar aghaidh.

Nóta:
(1) Bí cinnte go gcuirfidh tú do theorannóir mar an gcéanna le "///" san fho-thástáil a ghabhann leis an doiciméad idir gach cuid den téacs is mian leat a dheighilt. Chomh maith leis sin, is féidir leat athrú "///" le haon teorantóirí chun freastal ar do riachtanas.
(2) Féadfaidh tú na doiciméid a athrú "Nótaí" san fho-Tástáil a oireann do do riachtanais.
(3) Agus sábhálfar na doiciméid scoilteadh go dtí an áit chéanna leis an gcomhad bunaidh.
(4) Ní gá duit teorantóir a chur le deireadh an chomhaid bhunaidh, má dhéanann tú, beidh doiciméad bán ann tar éis a scoilteadh.

Seo VBA eile chun cabhrú leat doiciméad Word amháin a roinnt go iolrach de réir leathanaigh i Word. Déan mar a leanas le do thoil:

1. Brúigh Alt + F11 eochracha le chéile chun an fhuinneog Microsoft Visual Basic for Application a oscailt;

2. Cliceáil Ionsáigh > Modúil, agus ansin greamaigh faoi bhun chód VBA isteach i bhfuinneog nua an Mhodúil oscailte.

VBA: Roinn Doiciméad ina Ildhoiciméid de réir Leathanach i Word

Sub SplitIntoPages()
Dim docMultiple As Document
Dim docSingle As Document
Dim rngPage As Range
Dim iCurrentPage As Integer
Dim iPageCount As Integer
Dim strNewFileName As String
Application.ScreenUpdating = False 'Makes the code run faster and reduces screen _
flicker a bit.
Set docMultiple = ActiveDocument 'Work on the active document _
(the one currently containing the Selection)
Set rngPage = docMultiple.Range 'instantiate the range object
iCurrentPage = 1
'get the document's page count
iPageCount = docMultiple.Content.ComputeStatistics(wdStatisticPages)
Do Until iCurrentPage > iPageCount
If iCurrentPage = iPageCount Then
rngPage.End = ActiveDocument.Range.End 'last page (there won't be a next page)
Else
'Find the beginning of the next page
'Must use the Selection object. The Range.Goto method will not work on a page
Selection.GoTo wdGoToPage, wdGoToAbsolute, iCurrentPage + 1
'Set the end of the range to the point between the pages
rngPage.End = Selection.Start
End If
rngPage.Copy 'copy the page into the Windows clipboard
Set docSingle = Documents.Add 'create a new document
docSingle.Range.Paste 'paste the clipboard contents to the new document
'remove any manual page break to prevent a second blank
docSingle.Range.Find.Execute Findtext:="^m", ReplaceWith:=""
'build a new sequentially-numbered file name based on the original multi-paged file name and path
strNewFileName = Replace(docMultiple.FullName, ".doc", "_" & Right$("000" & iCurrentPage, 4) & ".doc")
docSingle.SaveAs strNewFileName 'save the new single-paged document
iCurrentPage = iCurrentPage + 1 'move to the next page
docSingle.Close 'close the new document
rngPage.Collapse wdCollapseEnd 'go to the next page
Loop 'go to the top of the do loop
Application.ScreenUpdating = True 'restore the screen updating
'Destroy the objects.
Set docMultiple = Nothing
Set docSingle = Nothing
Set rngPage = Nothing
End Sub 

3. Ansin cliceáil Rith cnaipe nó brúigh F5 eochair chun an VBA a chur i bhfeidhm.

Nóta: Sábhálfar na doiciméid scoilteadh san áit chéanna leis an gcomhad bunaidh.

Má tá tú Kutools for Word suiteáilte, is féidir leat a Scoilt feidhm chun doiciméad amháin a roinnt go héasca i ndoiciméid iolracha de réir leathanaigh, ceannteidil, briseadh ailt, nó briseadh leathanaigh de réir mar a theastaíonn uait i Word.

1. Cliceáil Kutools Plus > Scoilt chun a chumasú Scoilt gné.

2. Sa dialóg Scoilt tosaigh ar an scáileán, is féidir leat é seo a leanas a dhéanamh:

(1) Roghnaigh an bealach scoilte ón Scoilt ag liosta anuas.
Tacaíonn an ghné seo le 6 bhealach scoilte: ceannteideal 1, sosanna leathanaigh, briseadh rannáin, leathanaigh, gach n leathanach, agus raonta saincheaptha leathanaigh mar atá thíos an pictiúr a thaispeántar:

(2) Cliceáil ar an Brabhsáil cnaipe  a shonrú sábhálfaidh tú na cáipéisí roinnte san fhillteán ceann scríbe;

(3) Clóscríobh eochairfhocal mar réimír ainmneacha doiciméad nua sa Réimír Doiciméid bosca.

Leid:
(1) Má shonraíonn tú an scoilt déan an doiciméad reatha le Gach n leathanaigh, ní mór duit an uimhir sa Gach n leathanaigh bosca;

(2) Má shonraíonn tú an doiciméad reatha a roinnt de réir raonta leathanaigh saincheaptha, ní mór duit na raonta leathanaigh saincheaptha seo a iontráil scartha le camóga sa Leathanach bosca, mar shampla, cineál 1, 3-5, 12 sa bhosca.

3. Cliceáil ar an Ok cnaipe chun scoilteadh a thosú.

Ansin roinntear an doiciméad reatha ar an mbealach scoilte sonraithe, agus sábhálfar cáipéisí nua san fhillteán ceann scríbe ar an mórchóir.