Skip to main content

Excel IF fheidhm

Tá feidhm IF ar cheann de na feidhmeanna is simplí agus is úsáidí i leabhar oibre Excel. Déanann sé tástáil shimplí loighciúil a bhíonn ag brath ar thoradh na comparáide, agus faightear luach amháin ar ais más toradh TRUE é, nó luach eile más toradh FALSE é.


 Comhréir:

Is í an chomhréir don fheidhm IF in Excel:

=IF (logical_test, [value_if_true], [value_if_false])

doc más feidhm 2


 Argóintí:

  • logical_test: Riachtanach. Is é an coinníoll gur mhaith leat a thástáil.
  • value_if_true: Roghnach. Luach sonrach a theastaíonn uait a chur ar ais más TRUE an toradh loighciúil_test.
  • value_if_false: Roghnach. Luach a theastaíonn uait a fháil ar ais más é an toradh loighciúil_test FALSE.

nótaí:

1. Dá luach_if_true fágtha ar lár:

  • Má tá an luach_if_true fágtar argóint ar lár i bhfeidhm IF, mar shampla camóg díreach tar éis an loighciúil_test, fillfidh sé nialas nuair a chomhlíonfar an coinníoll. Mar shampla: =IF(C2>100,, "Low ").
  • Más mian leat cill bhán a úsáid in ionad an nialas má chomhlíontar an coinníoll, ba cheart duit luachana dúbailte "" a iontráil sa dara paraiméadar, mar seo: =IF(C2>100, "", "Low").
doc más feidhm 3 doc más feidhm 4

2. Dá luach_if_false fágtha ar lár:

  • Má tá an luach_if_false fágtar an paraiméadar ar lár san fheidhm IF, tabharfaidh sé CEOL ar ais nuair nach gcomhlíontar an coinníoll sonraithe. Mar: =IF(C2>100, "High").
  • Má chuireann tú camóg i ndiaidh na hargóinte value_if_true, fillfidh sé nialas ar ais nuair nach gcomhlíontar an coinníoll sonraithe. Mar: =IF(C2>100, "High" ,).
  • Má chuireann tú luachana dúbailte "" isteach sa tríú paraiméadar, fillfidh cill folamh mura gcomhlíontar an coinníoll. Mar: =IF(C2>100, "High" , "").
doc más feidhm 5 doc más feidhm 6 doc más feidhm 7

 Tuairisceán:

Déan tástáil ar riocht ar leith, faigh ar ais an luach comhfhreagrach a sholáthraíonn tú do TRUE nó FALSE.


 Samplaí:

Sampla 1: Feidhm shimplí IF a úsáid le haghaidh uimhreacha

Mar shampla, le tuiscint, ba mhaith leat liosta luachanna a thástáil, má tá an luach níos mó ná luach sonrach 100, taispeántar téacs “Maith”, mura bhfuil, seoltar téacs “Droch” ar ais.

Cuir isteach an fhoirmle thíos, agus gheobhaidh tú an toradh thíos de réir mar is gá duit.

=IF(B2>100,"Good","Bad")

doc más feidhm 8


Sampla 2: Feidhm IF a úsáid le haghaidh luachanna téacs

Cás 1: Feidhm IF maidir le luachanna téacs le cás neamhíogair:

Anseo, tá tábla agam le liosta Tascanna agus Stádas Críochnaithe, anois, ba mhaith liom a fháil amach cé na tascanna a gcaithfear dul ar aghaidh, agus cé na cinn nach gá. Nuair a bheidh an téacs i gColún C críochnaithe, taispeánfar “Níl”, ar shlí eile, seolfar “Tá” ar ais.

Cuir an fhoirmle seo a leanas i bhfeidhm, le do thoil anois, fillfidh an cill “Níl” nuair a thaispeánfar an téacs i gcolún C mar “chomhlánaithe”, is cuma má tá sé uachtarach nó cás íochtair; má chuirtear téacs eile i gcolún C, “Tá” ar ais. Féach an pictiúr:

=IF(C2="completed", "No", "Yes")

doc más feidhm 9

Cás 2: Feidhm IF maidir le luachanna téacs le cás-íogair:

Chun luachanna an téacs a thástáil le cás-íogair, ba cheart duit an fheidhm IF a chomhcheangal leis an bhfeidhm EXACT, cuir iarratas isteach faoin bhfoirmle le do thoil, ansin ní aithneofar ach an téacs leis an mheaitseáil bheacht, agus gheobhaidh tú an toradh thíos mar is mian leat:

=IF(EXACT(C2,"COMPLETED"), "No", "Yes")

doc más feidhm 10

Cás 3: Feidhm IF maidir le luachanna téacs le comhoiriúnú páirteach:

Uaireanta, ní mór duit na luachanna cille a sheiceáil bunaithe ar pháirt-théacs, sa chás seo, ba cheart duit na feidhmeanna IF, ISNUMBER agus SEARCH a úsáid le chéile.

Mar shampla, más mian leat na cealla ina bhfuil an téacs “comp” a sheiceáil, agus na luachanna comhfhreagracha a thabhairt ar ais, cuir an fhoirmle thíos i bhfeidhm. Agus gheobhaidh tú an toradh mar atá thíos ar an scáileán a thaispeántar:

=IF(ISNUMBER(SEARCH("comp",C2)), "No", "Yes")

doc más feidhm 11

Nótaí:

  • 1. Cuirtear an fheidhm SEARCH i bhfeidhm ar théacs le cás neamhíogair, más mian leat an téacs a sheiceáil le cás-íogair, ba cheart duit feidhm FIND a chur in ionad na feidhme SEARCH. Mar seo:=IF(ISNUMBER(FIND("comp",C2)), "No", "Yes")
  • 2. Na luachanna téacs mar pharaiméadair i bhfoirmlí IF, ní mór duit iad a iamh i "luachana dúbailte".

Sampla 3: Feidhm IF a úsáid le haghaidh luachanna dáta

Cás 1: Feidhm IF maidir le dátaí chun dátaí a chur i gcomparáid le dáta sonrach:

Más mian leat dátaí a chur i gcomparáid lena chéile chun a sheiceáil an bhfuil siad níos mó nó níos lú ná dáta sonrach, is féidir le feidhm IF fabhar a dhéanamh duit freisin. Toisc nach féidir le feidhm IF formáid dáta a aithint, ba cheart duit feidhm DATEVALUE a chomhcheangal leis.

Cuir an fhoirmle seo i bhfeidhm, le do thoil, nuair a bheidh an dáta níos mó ná 4/15/2019, seolfar “Tá” ar ais, ar shlí eile, seolfaidh an fhoirmle téacs “Níl” ar ais, féach an scáileán:

=IF(D4>DATEVALUE("4/15/2019"), "Yes", "No")

doc más feidhm 12

nótaí: San fhoirmle thuas, is féidir leat an tagairt cille a úsáid go díreach gan an fheidhm DATEVALUE a úsáid freisin. Mar seo: =IF(D4>$D$1, "Yes", "No").

doc más feidhm 13

Cás 2: Má tá feidhm IF maidir le dátaí chun dátaí a sheiceáil níos mó nó níos lú ná 30 lá:

Más mian leat na dátaí is mó nó níos lú ná 30 lá ón dáta reatha a shainaithint, féadfaidh tú an fheidhm TODAY a chomhcheangal leis an bhfeidhm IF.

Iontráil an fhoirmle seo le do thoil:

Sainaithin an dáta is sine ná 30 lá: =IF(TODAY()-C4>30,"Older date","")

Sainaithin an dáta is faide ná 30 lá: =IF(C4-TODAY()>30, "Future date", "")

doc más feidhm 14 doc más feidhm 15

Nóta: Más mian leat an dá thoradh a chur i gcolún amháin, ní mór duit feidhm neadaithe IF a úsáid mar seo:

=IF(C4-TODAY()>30, "Future date", IF(TODAY()-C4>30, "Older date", ""))

doc más feidhm 16


Sampla 4: Feidhm IF a úsáid le AND, NÓ feidhm le chéile

Is gnáthúsáid dúinn na feidhmeanna IF, AGUS, NÓ a chur le chéile in Excel.

Cás 1: Úsáid feidhm IF le AND feidhmeanna chun a sheiceáil an bhfuil na coinníollacha uile fíor:

Ba mhaith liom a sheiceáil an gcomhlíontar na coinníollacha go léir a leag mé síos, mar shampla: Tá B4 Dearg, tá C4 Beag agus D4> 200. Má tá na coinníollacha go léir TURE, marcáil an toradh mar “Tá”; Más FALSE ceachtar coinníoll, ansin seol “Níl”.

Cuir an fhoirmle seo i bhfeidhm, le do thoil, agus gheobhaidh tú an toradh mar a leanas an pictiúr a thaispeántar:

=IF(AND(B4="Red",C4="Small", D4>200),"Yes","No")

doc más feidhm 17

Cás 2: Is fíor an fheidhm IF a úsáid le feidhmeanna NÓ chun aon cheann de na coinníollacha a sheiceáil:

Is féidir leat feidhmeanna IF agus OR a úsáid freisin chun a sheiceáil an bhfuil aon cheann de na coinníollacha fíor, mar shampla, ba mhaith liom a aithint an bhfuil an téacs “Gorm” nó “Dearg” sa chill i gcolún B, más téacs i gcolún B é, Taispeántar Sea, ar shlí eile, ní chuirtear Níl ar ais.

Anseo, ba cheart duit an fhoirmle seo a chur i bhfeidhm, agus taispeánfar an toradh thíos:

=IF(OR(B4="Red",B4="Blue"),"Yes","No")

doc más feidhm 18

Cás 3: An fheidhm IF a úsáid le feidhmeanna AND agus OR le chéile:

Sa sampla seo, comhcheanglóidh mé an fheidhm IF leis an dá fheidhm AND & OR ag an am céanna. Ag rá, ba cheart duit na coinníollacha seo a leanas a sheiceáil:

  • Condition 1: Column B = “Red” and Column D > 300;
  • Condition 2: Column B = “Blue” and Column D > 300.

Má chomhlíontar ceachtar de na coinníollacha thuas, tugtar Cluiche ar ais, ar shlí eile, Uimh.

Úsáid an fhoirmle seo le do thoil, agus gheobhaidh tú an toradh thíos de réir mar a theastaíonn uait:

=IF(AND(OR(B4="Red",B4= "Blue"), D4>300), "Match", "No")

doc más feidhm 19


Sampla 5: Feidhm neadaithe IF a úsáid

Úsáidtear feidhm IF chun riocht a thástáil agus luach amháin a thabhairt ar ais má chomhlíontar an coinníoll agus luach eile mura gcomhlíontar é. Ach, uaireanta, ba cheart go mbeadh ort níos mó ná coinníoll amháin a sheiceáil ag an am céanna agus luachanna difriúla a thabhairt ar ais, is féidir leat Nested IF a úsáid chun an post seo a réiteach.

Ráiteas neadaithe IF a chomhcheanglaíonn ilchoinníollacha IF, ciallaíonn sé ráiteas IF a chur taobh istigh de ráiteas IF eile agus an próiseas sin a athdhéanamh arís agus arís eile.

Is í an chomhréir le haghaidh feidhm Nested IF in Excel:

=IF (condition1, result1, IF (condition2, result2, IF (condition3, result3,…)))

nótaí: In Excel 2007 agus leaganacha níos déanaí, is féidir leat suas le 64 feidhm IF a neadú i bhfoirmle amháin, agus in Excel 2003 agus i leaganacha níos luaithe, ní féidir ach 7 bhfeidhm neadaithe IF a úsáid.

Cás 1: Feidhm neadaithe IF chun ilchoinníollacha a sheiceáil:

Úsáid clasaiceach den fheidhm Nested IF is ea grád litreach a shannadh do gach mac léinn bunaithe ar a scóir. Mar shampla, tá tábla agat le mic léinn agus a gcuid scóir scrúduithe, anois ba mhaith leat na scóir a rangú leis na coinníollacha seo a leanas:

doc más feidhm 20

Cuir an fhoirmle seo i bhfeidhm le do thoil, agus gheobhaidh tú an toradh thíos, má tá an scór níos mó nó cothrom le 90, tá an grád “Sármhaith”, má tá an scór níos mó nó cothrom le 80, tá an grád “Go maith”, má tá an scór níos mó nó cothrom le 60, tá an grád “Meánach”, ar shlí eile, tá an grád “Bocht”.

=IF(C2>=90, "Excellent", IF(C2>=80, "Good", IF(C2>=60, "Medium", "Poor")))

doc más feidhm 21

Míniú ar an bhfoirmle thuas:

doc más feidhm 22
  • IF(check if C2>=90, if true - returns "Excellent", or else
  • IF(check if C2>=80, if true - returns "Good", or else
  • IF(check if C2>=60, if true - returns "Medium", if false - returns "Poor")))

Cás 2: Feidhm neadaithe IF chun praghas a ríomh bunaithe ar chainníocht:

Is féidir feidhm Nested IF a úsáid freisin chun praghas an táirge a ríomh bunaithe ar chainníocht.

Mar shampla, ba mhaith leat briseadh praghais a sholáthar do chustaiméirí bunaithe ar chainníocht, níos mó cainníochta a cheannaíonn siad, níos mó lascaine a gheobhaidh siad mar atá faoi bhun an scáileáin a thaispeántar.

doc más feidhm 23

Toisc gurb ionann an praghas iomlán agus an chainníocht agus iolraigh an praghas, mar sin ba cheart duit an chainníocht shonraithe a iolrú faoin luach a chuireann Ifs neadaithe ar ais. Úsáid an fhoirmle seo le do thoil:

=D2*IF(D2>=101,16, IF(D2>=50, 21, IF(D2>=25, 26, IF( D2>=11, 30, IF(D2>=1, 39, "")))))

doc más feidhm 24

nótaí: Is féidir leat na tagairtí cille a úsáid freisin chun na huimhreacha praghsanna statacha a athsholáthar, nuair nach n-athraíonn na sonraí foinse, níor cheart go mbeadh ort an fhoirmle a nuashonrú, bain úsáid as an bhfoirmle seo le do thoil: =D2*IF(D2>=101, B6, IF(D2>=50, B5, IF(D2>=25, B4, IF( D2>=11, B3, IF(D2>=1, B2, "")))))

doc más feidhm 25

Leideanna: Agus an fheidhm IF á úsáid agat chun tástáil a dhéanamh, is féidir leat na hoibreoirí loighciúla seo a leanas a úsáid:

oibreoir Ciall Sampla Tuairisc
> Níos fearr ná =IF(A1>10, "OK",) Má tá an líon i gcill A1 níos mó ná 10, filleann an fhoirmle “OK”; ar shlí eile tugtar 0 ar ais.
< Níos lú ná =IF(A1<10, "OK", "") Má tá an líon i gcill A1 níos lú ná 10, filleann an fhoirmle “OK”; ar shlí eile tugtar cill folamh ar ais.
>= Níos mó ná nó cothrom le =IF(A1>=10, "OK", "Bad") Má tá an líon i gcill A1 níos mó ná nó cothrom le 10, fillfidh sé “OK”; ar shlí eile, taispeántar "Droch".
<= Níos lú ná nó cothrom le =IF(A1<=10, "OK", "No") Má tá an líon i gcill A1 níos lú ná nó cothrom le 10, filleann sé "ceart go leor"; murach sin, tugtar “Níl” ar ais.
= Cothrom le =IF(A1=10, "OK", "No") Má tá an uimhir i gcill A1 cothrom le 10, filleann sé "OK"; ar shlí eile taispeánann sé "Níl".
<> Ní comhionann le =IF(A1<>10, "No", "OK") Mura bhfuil an uimhir i gcill A1 cothrom le 10, filleann an fhoirmle "Níl"; a mhalairt - "Ceart go leor".

Na hUirlisí Táirgiúlachta Oifige is Fearr

Kutools for Excel - Cabhraíonn sé leat Seasamh Amach ón Slua

🤖 Kutools AI Aide: anailís sonraí a réabhlóidiú bunaithe ar: Forghníomhú Chliste   |  Gin Cód  |  Cruthaigh Foirmlí Saincheaptha  |  Anailís a dhéanamh ar Sonraí agus Cairteacha a Ghin  |  Feidhmeanna Kutools a agairt...
Gnéithe Coitianta: Faigh, Aibhsigh nó Aithnigh Dúblaigh  |  Scrios Sraitheanna Bána  |  Comhcheangail Colúin nó Cealla gan Sonraí a Chailleadh  |  Babhta gan Foirmle ...
Super VLookup: Ilchritéir  |  Illuach  |  Trasna Il-Bileoga  |  Amharc doiléir...
Adv. Liosta anuas: Liosta anuas éasca  |  Liosta anuas Cleithiúnach  |  Liosta Buail Isteach Ilroghnacha...
Bainisteoir Colún: Cuir Líon Sonrach Colún leis  |  Colúin Bog  |  Scoránaigh Stádas Infheictheachta na gColún Ceilte  Cuir Colúin i gcomparáid le Roghnaigh Cealla Mar an gcéanna & Éagsúla ...
Gnéithe Réadmhaoin: Fócas Eangaí  |  Amharc Dearaidh  |  Barra Mór na Foirmle  |  Leabhar Oibre & Bainisteoir Bileog | Leabharlann Acmhainní (Uaththéacs)  |  Piocálaí Dáta  |  Comhcheangail Bileoga Oibre  |  Criptigh/Díchriptigh Cealla  |  Seol Ríomhphost trí Liosta  |  Scagaire Super  |  Scagaire Speisialta (scagaire trom/iodálach/stailc tríd...) ...
Barr 15 Uirlisí12 Téacs uirlisí (Cuir Téacs, Bain Carachtair ...)  |  50 + Cairt cineálacha (Cairt Gantt ...)  |  40+ Praiticiúil Foirmlí (Ríomh aois bunaithe ar lá breithe ...)  |  19 Insertion uirlisí (Cuir isteach Cód QR, Ionsáigh Pictiúr ón gCosán ...)  |  12 Tiontú uirlisí (Uimhreacha le Focail, Comhshó Airgeadra ...)  |  7 Cumaisc & Scoilt uirlisí (Sraitheanna Comhcheangail Casta, Scoilt Excel Cealla ...)  |  ... agus eile

Tá os cionn 300 Gnéithe ag Kutools le haghaidh Excel, A chinntiú nach bhfuil uait ach cliceáil ar shiúl...

Tuairisc


Cluaisín Oifige - Cumasaigh Léitheoireacht agus Eagarthóireacht Táblaithe i Microsoft Office (Excel san áireamh)

  • Soicind le hathrú idir an iliomad doiciméad oscailte!
  • Laghdaigh na céadta cad a tharlaíonn nuair luch duit gach lá, slán a fhágáil le lámh na luiche.
  • Méadaíonn do tháirgiúlacht 50% agus tú ag féachaint ar agus ag eagarthóireacht iliomad doiciméad.
  • Tugann sé Cluaisíní Éifeachtacha chuig Oifig (cuir Excel san áireamh), Just Like Chrome, Edge agus Firefox.
Comments (0)
No ratings yet. Be the first to rate!
There are no comments posted here yet
Please leave your comments in English
Posting as Guest
×
Rate this post:
0   Characters
Suggested Locations