Note: The other languages of the website are Google-translated. Back to English

Excel SUMPRODUCT fheidhm

In Excel, is féidir an fheidhm SUMPRODUCT a úsáid chun dhá cholún nó eagair nó níos mó a iolrú le chéile, agus ansin suim na dtáirgí a fháil. Déanta na fírinne, is feidhm úsáideach í an SUMPRODUCT a chabhróidh le luachanna cille a chomhaireamh nó a shuimiú le critéir iolracha mar an fheidhm COUNTIFS nó SUMIFS. Tabharfaidh an t-alt seo isteach an chomhréir feidhme agus roinnt samplaí don fheidhm SUMPRODUCT seo.


 Comhréir:

Is í an chomhréir don fheidhm SUMPRODUCT in Excel:

=SUMPRODUCT (array1, [array2], ...)

 Argóintí:

  • array1: Riachtanach. An chéad sraith nó raon cealla is mian leat a iolrú agus ansin cuir leo.
  • array2: Roghnach. An dara sraith nó raon cealla is mian leat a iolrú agus ansin cuir leo.

Nótaí:

  • 1. Má tá luachanna neamh-uimhriúla i do raon, déileálann an SUMPRODUCT leo mar nialais.
  • 2. Má tá líon difriúil sraitheanna agus colún ag na eagair nó na raonta, fillfidh an fheidhm SUMPRODUCT #VALUE! earráid.
  • 3. Má tá tástálacha loighciúla sna hailtí, cruthóidh siad luachanna TRUE agus FALSE. I bhformhór na gcásanna, níor mhór duit iad a thiontú go 1 agus 0 tríd an oibreoir dúbailte unary (-) a úsáid.
  • 4. Is féidir le feidhm SUMPRODUCT suas le 255 argóint a láimhseáil in Excel 2007 agus i leaganacha níos déanaí, agus gan ach 30 argóint i leaganacha Excel níos luaithe.
  • 5. Ní thacaíonn SUMPRODUCT le carachtair cárta fiáin.

 Tuairisceán:

Tabhair toradh eagair iolraithe agus achoimrithe ar ais.


 Samplaí:

Sampla 1: Úsáid bhunúsach na feidhme SUMPRODUCT

Is é bunúsáid an SUMPRODUCT ná dhá cholún a iolrú agus ansin iad a chur suas, mar shampla, tá na sonraí scáileáin seo a leanas agat, anois ba mhaith leat an t-ordú agus an praghas aonaid a iolrú, agus ansin na torthaí iolraithe go léir a iolrú le chéile chun an Praghas iomlán.

Chun déileáil leis an tasc seo, cuir an fhoirmle thíos i bhfeidhm:

=SUMPRODUCT(B2:B7,C2:C7)

Míniú: An fhoirmle seo SUMPRODUCT(B2:B7,C2:C7) = B2*C2+B3*C3+B4*C4+B5*C5+B6*C6+B7*C7.

Agus ansin, brúigh Iontráil eochair, déantar na cealla i gcolún B a iolrú faoina chealla comhfhreagracha sa tsraith chéanna de cholún C, agus cuirtear na torthaí leis. Féach an pictiúr:


Sampla 2: Suimchealla a bhfuil ilchritéir acu le feidhm SUMPRODUCT

Seachas feidhm SUMIFS chun luachanna cille a shuimiú bunaithe ar ilchoinníollacha, is féidir leis an bhfeidhm SUMPRODUCT an post seo a réiteach go tapa agus go héasca.


Cás 1: Luachanna suime cille má tá téacs sonrach ann i gcolún eile

Ag ceapadh, tá tábla sonraí agat mar atá thíos an pictiúr a thaispeántar, anois, ba mhaith leat an praghas iomlán ar KTE an táirge a ríomh agus David an t-ainm atá air, conas a d’fhéadfá a dhéanamh tríd an bhfoirmle SUMPRODUCT a úsáid in Excel?

1. Iontráil nó cóipeáil aon cheann de na foirmlí thíos i gcill bhán:

=SUMPRODUCT(--(A2:A12="KTE"), --(B2:B12="David"), D2:D12)
=SUMPRODUCT((A2:A12="KTE")*(B2:B12="David")*D2:D12)
  • Leideanna: San fhoirmle thuas:
  • A2: A12 = "KTE": an bhfuil na chéad chritéir_range agus critéir ar mhaith leat suim a dhéanamh bunaithe orthu.
  • B2: B12 = "David": an bhfuil an dara critéar_range agus na critéir ar mhaith leat suim a dhéanamh bunaithe orthu.
  • D2: D12: an bhfuil an raon suimeanna ar mhaith leat na luachanna cille a achoimriú.

2. Ansin, brúigh Iontráil eochair chun an toradh a fháil de réir mar a theastaíonn uait:


Cás 2: Suimchealla a bhfuil ilchritéir acu le loighic NÓ

Chun cealla a shuimiú bunaithe ar ilchritéir le loighic NÓ, ba cheart duit an tsiombail móide (+) a úsáid chun na dálaí iolracha a cheangal le chéile laistigh den fheidhm SUMPRODUCT.

Mar shampla, ba mhaith liom praghas iomlán an táirge KTE agus KTO i gcolún A a lua mar atá thíos an pictiúr a thaispeántar:

Cuir an fhoirmle seo a leanas i gcill bhán le do thoil:

=SUMPRODUCT((A2:A12="KTE")+(A2:A12="KTO"), C2:C12)

Agus ansin, brúigh Iontráil eochair, ríomhadh praghas iomlán an táirge KTE agus KTO, féach an scáileán:


Cás3: Cealla suime le critéir iolracha le loighic OR agus AND

I roinnt cásanna, b’fhéidir go mbeidh ort cealla a shuimiú le loighic NÓ agus AGUS araon ag an am céanna. Is féidir leis an bhfeidhm SUMPRODUCE an post seo a réiteach gan stró.

Réiltín (*) úsáidtear mar oibreoir AND.

Siombail móide (+) úsáidtear mar oibreoir NÓ.

Feicfimid sampla, chun an praghas iomlán a fháil ar cén táirge é KTE agus KTO nuair is mó an díolachán ná 200.

Ba cheart duit an fhoirmle thíos a chóipeáil nó a iontráil:

=SUMPRODUCT((B2:B12>200)*((A2:A12="KTE")+(A2:A12="KTO"))*C2:C12)

Ansin brúigh Iontráil eochair chun an toradh a fháil de réir mar a theastaíonn uait:


Sampla 3: Déan cealla a chomhaireamh a bhfuil ilchritéir acu le feidhm SUMPRODUCT

Go ginearálta, is féidir leis an bhfeidhm SUMPRODUCT seo cabhrú linn na cealla a chomhaireamh le critéir iolracha in Excel. Mar an gcéanna leis na luachanna suime, ní gá duit ach an argóint sum_range a bhaint den fhoirmle.


Cás1: Líon cealla a bhfuil ilchritéir acu le loighic AND

Anseo, ba mhaith liom na cealla gur KTE an táirge sin a chomhaireamh agus gur mó an díolachán ná 200. Mar sin, bain úsáid as ceann ar bith de na foirmlí thíos:

=SUMPRODUCT(--(A2:A12="KTE"), --(B2:B12>200))
=SUMPRODUCT((A2:A12="KTE")*(B2:B12>200))
  • Leideanna: San fhoirmle thuas:
  • A2: A12 = "KTE": an bhfuil na chéad chritéir_range agus na critéir a theastaíonn uait a chomhaireamh bunaithe ar.
  • B2: B12> 200: an bhfuil an dara critéar_range agus na critéir a theastaíonn uait a chomhaireamh bunaithe ar.

Agus ansin, brúigh Iontráil eochair chun uimhir an toraidh a fháil:


Cás 2: Líon cealla a bhfuil ilchritéir acu le loighic NÓ

Chun líon na dtáirgí KTE agus KTO i gcolún A a chomhaireamh, cuir an fhoirmle seo i bhfeidhm:

=SUMPRODUCT((A2:A12="KTE")+(A2:A12="KTO"))

Agus ansin, brúigh Iontráil eochair chun uimhir an táirge KTE agus KTO a fháil. Féach an pictiúr:


Cás3: Líon cealla a bhfuil ilchritéir acu le loighic OR agus AND

Chun líon na dtáirgí KTE agus KTO ar mó a ndíol ná 200 a chomhaireamh, ba cheart duit an fhoirmle seo a leanas a chur i bhfeidhm:

=SUMPRODUCT((B2:B12>200)*((A2:A12="KTE")+(A2:A12="KTO")))

Ansin, brúigh Iontráil eochair chun líon na dtorthaí a theastaíonn uait a fháil:


Sampla 4: Ríomh an meán ualaithe le feidhm SUMPRODUCT

De ghnáth, is féidir linn meán raon na gcealla a ríomh go tapa agus go héasca. Ach, más mian leat meán liosta luachanna le leibhéil éagsúla ábharthachta a ríomh, ciallaíonn sé an meán ualaithe a ríomh. Níl aon fheidhm dhíreach ann chun é a fháil in Excel. Ach, is féidir leis an bhfeidhm SUMPRODUCT cabhrú leat déileáil leis.

Mar shampla, tá tábla staitisticí grád agam do mhac léinn, glacann gach tasc an meáchan difriúil mar atá thíos an pictiúr a thaispeántar.

Chun an meán ualaithe a ríomh, bain úsáid as an bhfoirmle seo a leanas:

=SUMPRODUCT(B2:B6, C2:C6) / SUM(C2:C6)

Míniú: An fhoirmle seo: SUMPRODUCT(B2:B6, C2:C6) / SUM(C2:C6) = (B2*C2+B3*C3+B4*C4+B5*C5+B6*C6)/(C2+C3+C4+C5+C6)

Agus ansin, brúigh Iontráil eochair, ríomhadh an meán ualaithe ag an am céanna, féach an pictiúr:


 Tuilleadh alt le feidhm SUMPRODUCT:

  • Countif Luach Sonrach Thar Il Bileoga Oibre
  • Ag ceapadh, tá iliomad bileoga oibre agam ina bhfuil na sonraí seo a leanas, agus anois, ba mhaith liom an líon tarlú de luach sonrach “Excel” a fháil ó bhileoga oibre tráchtais. Conas a d’fhéadfainn luachanna ar leith a chomhaireamh thar iliomad bileoga oibre?
  • Faigh agus Faigh an Luach is Mó Bunaithe ar Chritéir Il in Excel
  • In Excel, is féidir linn an fheidhm max a chur i bhfeidhm chun an líon is mó a fháil chomh tapa agus is féidir linn. Ach, uaireanta, b’fhéidir go mbeidh ort an luach is mó a fháil bunaithe ar chritéir áirithe, conas a d’fhéadfá déileáil leis an tasc seo in Excel?
  • Ríomh Meán Ualaithe in Excel
  • Mar shampla, tá liosta siopadóireachta agat le praghsanna, meáchain agus méideanna. Is féidir leat an meánphraghas a ríomh go héasca leis an bhfeidhm AVERAGE in Excel. Ach cad más meánphraghas ualaithe é? San Airteagal seo, tabharfaidh mé modh isteach chun an meán ualaithe a ríomh, chomh maith le modh chun meán ualaithe a ríomh má chomhlíontar critéir shonracha in Excel.

Na hUirlisí Táirgiúlachta Oifige is Fearr

Kutools for Excel - Cabhraíonn sé leat Seasamh Amach ón Slua

Ar mhaith leat do chuid oibre laethúil a chríochnú go tapa agus go foirfe? Tugann Kutools le haghaidh Excel ardghnéithe cumhachtacha 300 (Comhcheangail leabhair oibre, suim de réir datha, inneachar cille scoilte, dáta a thiontú, agus mar sin de ...) agus sábháil 80% ama duit.

  • Deartha do 1500 cás oibre, cabhraíonn sé leat fadhbanna 80% Excel a réiteach.
  • Laghdaigh na mílte cad a tharlaíonn nuair méarchlár agus luch gach lá, faoiseamh a thabhairt do do shúile agus do lámha tuirseach.
  • Bí i do shaineolaí Excel i gceann 3 nóiméad. Ní gá cuimhneamh a thuilleadh ar aon fhoirmlí pianmhara agus cóid VBA.
  • Triail saor in aisce gan teorainn 30 lá. Ráthaíocht ar ais airgid 60 lá. Uasghrádú agus tacaíocht saor in aisce ar feadh 2 bhliain.
Ribín Excel (le Kutools le haghaidh Excel suiteáilte)

Cluaisín Oifige - Cumasaigh Léitheoireacht agus Eagarthóireacht Táblaithe i Microsoft Office (Excel san áireamh)

  • Soicind le hathrú idir an iliomad doiciméad oscailte!
  • Laghdaigh na céadta cad a tharlaíonn nuair luch duit gach lá, slán a fhágáil le lámh na luiche.
  • Méadaíonn do tháirgiúlacht 50% agus tú ag féachaint ar agus ag eagarthóireacht iliomad doiciméad.
  • Tugann Cluaisíní Éifeachtacha chuig an Oifig (Excel san áireamh), Díreach Cosúil le Chrome, Firefox, agus New Internet Explorer.
Urchar Scáileáin de Excel (le Office Tab suiteáilte)
Sórtáil tuairimí de réir
Comments (0)
Níl rátálacha ar bith fós. Bí ar an gcéad duine a rátáil!
Níl aon tráchtanna curtha suas anseo go fóill
Fág do chuid tuairimí
Ag postáil mar Aoi
×
Ráta an post seo:
0   Carachtair
Suímh Molta

Lean orainn

Cóipcheart © 2009 - www.extendoffice.com. | Gach ceart ar cosaint. Cumhachtaithe ag ExtendOffice. | léarscáil an tSuímh
Is trádmharcanna nó trádmharcanna cláraithe de chuid Microsoft Corporation sna Stáit Aontaithe agus / nó i dtíortha eile iad lógó Office agus Office.
Cosanta ag Sectigo SSL