Máistreacht a fháil ar Ráitis Neadaithe IF in Excel - Treoir Céim ar Chéim
In Excel, cé go bhfuil an fheidhm IF riachtanach do thástálacha loighciúla bunúsacha, is minic a éilíonn coinníollacha casta ráitis IF neadaithe le haghaidh próiseála sonraí feabhsaithe. Sa treoir chuimsitheach seo, clúdóimid go mion na bunghnéithe a bhaineann le neadú IF, ó chomhréir go feidhmeanna praiticiúla, lena n-áirítear teaglaim de neadaithe MÁ le coinníollacha AND/OR. Ina theannta sin, roinnfimid conas inléiteacht na bhfeidhmeanna IF neadaithe a fheabhsú chomh maith le roinnt leideanna faoi neadaithe IF, agus déanfaimid iniúchadh ar roghanna eile cumhachtacha mar VLOOKUP, IFS, agus níos mó chun oibríochtaí loighciúla casta a dhéanamh níos éasca le húsáid agus níos éifeachtaí.
- Ag déanamh neadaithe MÁ éasca é a léamh
- Ord na bhfeidhmeanna IF neadaithe
- Ba cheart caitheamh go héagsúil le huimhreacha agus le téacs
- Teorainneacha neadaithe MÁS
Feidhm Excel IF vs. Ráitis Neadaithe IF
Feidhmíonn an fheidhm IF agus na ráitis IF neadaithe in Excel críocha comhchosúla ach tá difríocht shuntasach eatarthu maidir lena gcastacht agus lena bhfeidhmiú.
- Tá an Comhréir:
=IF (logical_test, [value_if_true], [value_if_false]) - Teorainn: Ní féidir leis ach coinníoll amháin a láimhseáil ag an am, rud a fhágann nach bhfuil sé chomh hoiriúnach do chásanna cinnteoireachta níos casta a éilíonn go ndéanfaí measúnú ar iliomad critéir.
- Tá an Comhréir:
=IF( condition1, value_if_true1, IF( condition2, value_if_true2, value_if_false2 )) - Coimpléasc: Is féidir leis an iliomad coinníollacha a láimhseáil ach is féidir leis éirí casta agus deacair a léamh agus an iomarca sraitheanna neadaithe ann.
Úsáid neadaithe IF
Léiríonn an chuid seo úsáid bhunúsach na ráiteas IF neadaithe in Excel, lena n-áirítear comhréir, samplaí praiticiúla, agus conas iad a úsáid le coinníollacha AND nó OR.
Comhréir na neadaithe IF
Tá tuiscint ar chomhréir feidhme mar bhunús lena chur i bhfeidhm i gceart agus go héifeachtach in Excel. Let tús leis an chomhréir de neadaithe má ráitis.
Comhréire:
=IF(condition1, result1, IF(condition2, result2, IF(condition3, result3, result4)))
Argóintí:
- Condition1, Condition2, Condition3: These are the conditions you want to test. Each condition is evaluated in order, starting with Condition1.
- Result1: This is the value returned if Condition1 is TRUE.
- Result2: This value is returned if Condition1 is FALSE and Condition2 is TRUE. It's important to note that Result2 is only evaluated if Condition1 is FALSE.
- Result3: This value is returned if both Condition1 and Condition2 are FALSE, and Condition3 is TRUE. Essentially, for Result3 to be evaluated, the previous conditions (Condition1 and Condition2) must both be FALSE.
- Result4: This result is returned if all the conditions (Condition1, Condition2, and Condition3) are FALSE.
In short, this expression can be interpreted as follows:Test condition1, if TRUE, return result1, if FALSE,
test condition2, if TRUE, return result2, if FALSE,
test condition3, if TRUE, return result3, if FALSE,
return result4
Cuimhnigh, i struchtúr neadaithe MÁ, ní dhéantar gach coinníoll ina dhiaidh sin a mheas ach amháin má tá na coinníollacha go léir roimhe seo BRÉAGACH. Tá an seiceáil seicheamhach seo ríthábhachtach chun tuiscint a fháil ar an gcaoi a n-oibríonn IFanna neadaithe.
Samplaí praiticiúla de neadaithe IF
Anois, déanaimis tumadh isteach in úsáid neadaithe IF le dhá shampla praiticiúla.
Sampla 1: Córas Grádaithe
Mar a thaispeántar sa screenshot thíos, is dócha go bhfuil liosta de scóir na mac léinn agat agus gur mhaith leat gráid a shannadh bunaithe ar na scóir seo. Is féidir leat neadaithe IF a úsáid chun an tasc seo a chur i gcrích.
Roghnaigh ceall bán (C2 sa chás seo), cuir isteach an fhoirmle seo a leanas agus brúigh Iontráil chun an toradh a fháil. Ansin tarraing an Líon Láimhseáil síos chun an chuid eile de na torthaí a fháil.
=IF(B2>=90,$F$2,IF(B2>=80,$F$3,IF(B2>=70,$F$4,IF(B2>=60,$F$5,$F$6))))- Is féidir leat leibhéal an ghráid a shonrú go díreach san fhoirmle, ionas gur féidir an fhoirmle a athrú go:
=IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F")))) - Úsáidtear an fhoirmle seo chun grád (A, B, C, D, nó F) a shannadh bunaithe ar scór i gcill A2, ag baint úsáide as tairseacha grádaithe caighdeánacha. Is gnáthchás úsáide é do ráitis IF neadaithe i gcórais grádaithe acadúla.
- Míniú ar an bhfoirmle:
- A2>=90: Is é seo an chéad choinníoll seiceálacha an fhoirmle. Má tá an scór i gcill A2 níos mó ná nó cothrom le 90, filleann an fhoirmle "A".
- A2>=80: Má tá an chéad choinníoll bréagach (tá an scór níos lú ná 90), seiceálann sé an bhfuil A2 níos mó ná nó cothrom le 80. Más fíor, filleann sé "B".
- A2>=70: Mar an gcéanna, má tá an scór níos lú ná 80, seiceálann sé an bhfuil sé níos mó ná nó cothrom le 70. Más fíor, filleann sé "C".
- A2>=60: Má tá an scór níos lú ná 70, seiceálann an fhoirmle an bhfuil sé níos mó ná nó cothrom le 60. Más fíor, filleann sé "D".
- "F": Ar deireadh, mura gcomhlíontar aon cheann de na coinníollacha thuas (a chiallaíonn go bhfuil an scór níos lú ná 60), filleann an fhoirmle "F".
Sampla 2: Ríomh an Choimisiúin Díolacháin
Samhlaigh cás ina bhfaigheann ionadaithe díolacháin rátaí coimisiúin éagsúla bunaithe ar a ngnóthachtálacha díolacháin. Mar a thaispeántar sa screenshot thíos, ba mhaith leat coimisiún díoltóra a ríomh bunaithe ar na tairseacha díolacháin éagsúla seo, agus is féidir le ráitis neadaithe IF cabhrú leat le seo.
- 20% do dhíolacháin os cionn $20,000
- 15% le haghaidh díolacháin idir $10,000 agus $20,000
- 10% le haghaidh díolacháin faoi bhun $10,000
Roghnaigh ceall bán (C2 sa chás seo), cuir isteach an fhoirmle seo a leanas agus brúigh Iontráil chun an toradh a fháil. Ansin tarraing an Líon Láimhseáil síos chun an chuid eile de na torthaí a fháil.
=B2*IF(B2>20000,$F$2,IF(B2>=10000,$F$3,$F$4))
- Is féidir leat an ráta coimisiúin a shonrú go díreach san fhoirmle, ionas gur féidir an fhoirmle a athrú go:
=B2*IF(B2>20000, 20%, IF(B2>=10000, 15%, 10%)) - Úsáidtear an fhoirmle a sholáthraítear chun coimisiún díoltóirí a ríomh bunaithe ar a méid díolacháin, ag cur rátaí coimisiúin éagsúla i bhfeidhm ar thairseacha díolacháin éagsúla.
- Míniú ar an bhfoirmle:
- B2: Léiríonn sé seo an méid díolacháin don díoltóir, a úsáidtear mar bhonn chun an coimisiún a ríomh.
- IF(B2>20000, "20%", ...): Is é seo an chéad choinníoll a sheiceáil. Seiceálann sé an bhfuil an méid díolacháin i B2 níos mó ná 20,000. Má tá, úsáideann an fhoirmle ráta coimisiúin 20%.
- IF(B2>=10000, "15%", "10%): Má tá an chéad choinníoll bréagach (níl díolacháin níos mó ná 20,000), seiceann an fhoirmle an bhfuil na díolacháin comhionann le nó níos mó ná 10,000. Más fíor, baineann sé ráta coimisiúin 15%. Má tá an méid díolacháin níos lú ná 10,000, mainneachtainí an fhoirmle go ráta coimisiúin 10%.
Neadaithe má tá riocht AGUS / OR
Sa chuid seo, modhnaíonn mé an chéad sampla thuas "an córas grádaithe" chun a léiriú conas neadaithe MÁ le AGUS nó coinníoll OR in Excel a chomhcheangal. Sa sampla grádaithe athbhreithnithe, thug mé isteach coinníoll breise bunaithe ar "Ráta freastail".
Ag baint úsáide as neadaithe má tá AGUS riocht
Má chomhlíonann mac léinn an scór agus na critéir tinrimh, gheobhaidh sé treisiú grád. Mar shampla, mac léinn a bhfuil a scór 60 nó níos airde agus a bhfuil a ráta tinrimh 95% nó níos airde uasghrádaithe de réir leibhéal amháin, mar shampla ó A go A+, ó B go B+ agus mar sin de. Má bhíonn an ráta tinrimh faoi bhun 95%, áfach, leanfaidh an grádú na bunchritéir scórbhunaithe. I gcásanna den sórt sin, ní mór dúinn ráiteas IF neadaithe a úsáid le coinníoll AND.
Roghnaigh ceall bán (D2 sa chás seo), cuir isteach an fhoirmle seo a leanas agus brúigh Iontráil chun an toradh a fháil. Ansin tarraing an Líon Láimhseáil síos chun an chuid eile de na torthaí a fháil.
=IF(AND(B2>=60, C2>=95%),IF(B2>=90, "A+", IF(B2>=80, "B+", IF(B2>=70, "C+", "D+"))),IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F")))))
- AGUS seiceáil riocht:
AGUS(B2>=60, C2>=95%): Seiceálann an coinníoll AND ar dtús an bhfuil an dá choinníoll comhlíonta — scór an dalta 60 nó níos airde, agus an ráta tinrimh 95% nó níos mó. - Tasc grád nua:
IF(B2>=90, "A+", IF(B2>=80, "B+", IF(B2>=70, "C+", "D+"))): Má tá an dá choinníoll sa ráiteas AND fíor, seiceálann an fhoirmle scór an dalta ansin agus ardaíonn sé ac(h)uid grád faoi leibhéal amháin.- B2>=90: Má tá an scór 90 nó os a chionn, is é “A+". Tasc grád nua:
- B2>=80: Má tá an scór 80 nó níos airde (ach níos lú ná 90), is é an grád "B+".
- B2>=70: Má tá an scór 70 nó níos airde (ach níos lú ná 80), is é an grád "C+".
- B2>=60: Má tá an scór 60 nó níos airde (ach níos lú ná 70), is é an grád "D+".
- Tasc Grád Rialta:
IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F"))) ): Mura gcomhlíontar an coinníoll AND (bíodh an scór faoi bhun 80 nó má bhíonn an tinreamh faoi 95%), sannann an fhoirmle gráid chaighdeánacha.- B2>=90: Faigheann scór 90 nó níos airde "A".
- B2>=80: Faigheann scór 80 nó níos airde (ach níos lú ná 90) "B".
- B2>=70: Faigheann scór 70 nó níos airde (ach níos lú ná 80) "C".
- B2>=60: Faigheann scór 60 nó níos airde (ach níos lú ná 70) "D".
- Faigheann scóir faoi 60 "F".
Ag baint úsáide as neadaithe má tá riocht NÓ leis
Sa chás seo, ardófar grád dalta leibhéal amháin má tá a scór 95 nó níos airde, nó má tá a ráta tinrimh 95% nó níos mó. Seo mar is féidir linn é a chur i gcrích trí úsáid a bhaint as coinníollacha neadaithe IF agus OR.
Roghnaigh ceall bán (D2 sa chás seo), cuir isteach an fhoirmle seo a leanas agus brúigh Iontráil chun an toradh a fháil. Ansin tarraing an Líon Láimhseáil síos chun an chuid eile de na torthaí a fháil.
=IF(OR(B2>=95, C2>=95%),IF(B2>=90, "A+", IF(B2>=80, "B+", IF(B2>=70, "C+", IF(B2>=60, "D+", "F+")))),IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F")))))
- NÓ Seiceáil Coinníoll:
OR(B2>=95, C2>=95%): Seiceálann an fhoirmle ar dtús an bhfuil ceachtar de na coinníollacha fíor — tá scór an dalta 95 nó níos airde, nó an ráta tinrimh 95% nó níos airde. - Tasc Grád le Bónas:
IF(B2>=90, "A+", IF(B2>=80, "B+", IF(B2>=70, "C+", IF(B2>=60, "D+", "F+"))) ): Má tá ceachtar coinníoll sa ráiteas NÓ fíor, ardófar grád an mhic léinn leibhéal amháin.- B2>=90: Má tá an scór 90 nó níos airde, is é an grád "A+".
- B2>=80: Má tá an scór 80 nó níos airde (ach níos lú ná 90), is é an grád "B+".
- B2>=70: Má tá an scór 70 nó níos airde (ach níos lú ná 80), is é an grád "C+".
- B2>=60: Má tá an scór 60 nó níos airde (ach níos lú ná 70), is é an grád "D+".
- Seachas sin, is é an grád "F+".
- Tasc Grád Rialta:
IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F"))))): Mura gcomhlíontar ceachtar de na coinníollacha NÓ (tá an scór faoi bhun 95 agus an tinreamh faoi 95%), sannann an fhoirmle gráid chaighdeánacha.- B2>=90: Faigheann scór 90 nó níos airde "A".
- B2>=80: Faigheann scór 80 nó níos airde (ach níos lú ná 90) "B".
- B2>=70: Faigheann scór 70 nó níos airde (ach níos lú ná 80) "C".
- B2>=60: Faigheann scór 60 nó níos airde (ach níos lú ná 70) "D".
- Faigheann scóir faoi 60 "F".
Leideanna agus cleasanna le haghaidh neadaithe IF
Clúdaíonn an chuid seo ceithre leid agus cleas úsáideacha le haghaidh MÁ neadaithe.
Ag déanamh neadaithe MÁ éasca é a léamh
D'fhéadfadh cuma dhlúth a bheith ar ghnáthráiteas neadaithe IF ach is deacair é a thuiscint.
San fhoirmle seo a leanas, tá sé dúshlánach a aithint go tapa nuair a thagann deireadh le riocht amháin agus nuair a thosaíonn riocht eile, go háirithe de réir mar a mhéadaíonn an chastacht.
=IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F"))))Réiteach: Sosanna Líne agus Greanú a Chur Leis
Chun neadú a dhéanamh MÁS furasta a léamh, is féidir leat an fhoirmle a bhriseadh ina línte iolracha le gach MÁ neadaithe ar líne nua. Sa fhoirmle, cuir an cúrsóir roimh an IF agus brúigh an Alt + Iontráil eochracha.
Tar éis an fhoirmle thuas a bhriseadh, taispeánfar é mar seo a leanas:
=IF(A2>=90, "A",
IF(A2>=80, "B",
IF(A2>=70, "C",
IF(A2>=60, "D", "F")))
)Déanann an fhormáid seo níos soiléire cá bhfuil gach coinníoll agus an t-aschur comhfhreagrach, ag cur le hinléiteacht na foirmle.
Ord na bhfeidhmeanna IF neadaithe
Tá ord na gcoinníollacha loighciúla i bhfoirmle neadaithe IF ríthábhachtach toisc go gcinnfidh sé conas a dhéanann Excel na coinníollacha seo a mheas agus mar sin bíonn tionchar aige ar thoradh deiridh na foirmle.
Foirmle cheart
Sa chóras grádaithe mar shampla, úsáidimid an fhoirmle seo a leanas chun gráid a shannadh bunaithe ar scóir.
=IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F"))))
Déanann Excel na coinníollacha i bhfoirmle neadaithe IF a mheas go seicheamhach, ón gcéad choinníoll go dtí an ceann deireanach. Seiceálann an fhoirmle seo an scórthairseach is airde ar dtús (>=90 le haghaidh "A") agus ansin bogtar chuig na tairseacha níos ísle. Cinntíonn sé go gcuirtear scór i gcomparáid leis an ngrád is airde a cháilíonn sé dó. Má tá an chéad choinníoll fíor (A2>=90), filleann sé "A" agus ní dhéanann sé meastóireacht ar aon choinníollacha eile.
Foirmle ordaithe mícheart
Dá ndéanfaí ord na gcoinníollacha a aisiompú, ag tosú leis an tairseach is ísle, thabharfadh sé torthaí míchearta.
=IF(B2>=60, "D", IF(B2>=70, "C", IF(B2>=80, "B", IF(B2>=90, "A", "F"))))
San fhoirmle mhícheart seo, shásódh scór 95 an chéad choinníoll B2>=60 láithreach agus thabharfaí grád "D" dó go mícheart.
Ba cheart caitheamh go héagsúil le huimhreacha agus le téacs
Taispeánfaidh an chuid seo duit an chaoi a gcaitear go héagsúil le huimhreacha agus téacs i ráitis neadaithe IF.
Uimhreacha
Úsáidtear uimhreacha le haghaidh comparáidí agus ríomhanna uimhríochta. I ráitis IF neadaithe, is féidir leat uimhreacha a chur i gcomparáid go díreach trí úsáid a bhaint as oibreoirí amhail >, <, =, >=, agus <=.
Téacs
I ráitis IF neadaithe, ba cheart go mbeadh an téacs faoi iamh i Sleachta dúbailte. Féach ar na A, B, C , D agus F san fhoirmle seo a leanas:
=IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F"))))Teorainneacha neadaithe MÁS
Liostaíonn an chuid seo roinnt teorainneacha agus míbhuntáistí a bhaineann le IF neadaithe.
Castacht agus Inléiteacht:
Cé go gceadaíonn Excel duit suas le 64 feidhm IF éagsúla a neadú, níl sé inmholta ar chor ar bith é sin a dhéanamh. Dá mhéad leibhéil neadaithe is ea is casta a éiríonn an fhoirmle. Is féidir foirmlí atá deacair a léamh, a thuiscint agus a chothabháil a bheith mar thoradh air seo.
Seans maith le Earráid:
Ina theannta sin, d’fhéadfadh go n-éireodh ráitis Choimpléasc neadaithe go hearráidí agus go mbíonn sé dúshlánach iad a dhífhabhtú nó a mhodhnú.
Deacair a shíneadh nó a scála:
Má athraíonn do loighic nó má theastaíonn uait tuilleadh coinníollacha a chur leis, is féidir go mbeadh sé deacair IFanna atá neadaithe go domhain a mhodhnú nó a shíneadh.
Tá sé ríthábhachtach na teorainneacha seo a thuiscint chun ráitis IF neadaithe a úsáid go héifeachtach in Excel. Go minic, is féidir réitigh níos éifeachtúla agus níos inbhuanaithe a bheith mar thoradh ar IFanna neadaithe a chomhcheangal le feidhmeanna eile nó cineálacha cur chuige eile a lorg.
Roghanna eile seachas Nested IF
Liostaíonn an chuid seo roinnt feidhmeanna in Excel is féidir a úsáid mar roghanna eile seachas ráitis IF neadaithe.
Ag baint úsáide as VLOOKUP
Is féidir leat an fheidhm VLOOKUP a úsáid in ionad ráitis IF neadaithe chun an dá shampla praiticiúla thuas a bhaint amach. Seo mar is féidir leat é a dhéanamh:
Sampla 1: Córas Grádaithe le VLOOKUP
Anseo taispeánfaidh mé conas VLOOKUP a úsáid chun gráid a shannadh bunaithe ar scóir.
Céim 1: Cruthaigh Tábla Cuardaigh le haghaidh Gráid
Ar an gcéad dul síos, ní mór duit tábla cuardaigh a chruthú (amhail E1:F6 sa chás seo) don raon scór agus do na gráid chomhfhreagracha. nótaí: Ní mór na scóir sa chéad cholún den tábla a shórtáil in ord ardaitheach.
Céim 2: Cuir an fheidhm VLOOKUP i bhfeidhm chun gráid a shannadh
Roghnaigh ceall bán (C2 sa chás seo), cuir isteach an fhoirmle seo a leanas agus brúigh an Iontráil eochair chun an chéad ghrád a fháil. Roghnaigh an chill fhoirmle seo agus tarraing a Líon Láimhseáil síos chun an chuid eile de na gráid a fháil.
=VLOOKUP(B2,$E$2:$F$6,2,TRUE)
- Is é an luach 95 i gcill B2 an rud a chuardaíonn VLOOKUP sa chéad cholún den tábla cuardaigh ($E$2:$F$6). Má aimsítear é, filleann sé an grád comhfhreagrach ón dara colún den tábla, atá suite sa tsraith chéanna leis an luach comhoiriúnaithe.
- Cuimhnigh an tagairt tábla cuardaigh a dhéanamh absalóideach (cuir na comharthaí dollar ($) roimh na tagairtí), rud a chiallaíonn nach n-athróidh an tagairt má chóipeáiltear an fhoirmle chuig cill eile.
- Chun tuilleadh eolais a fháil faoin bhfeidhm VLOOKUP, tabhair cuairt ar an leathanach seo.
Sampla 2: Ríomh an Choimisiúin Díolacháin le VLOOKUP
Is féidir leat VLOOKUP a úsáid freisin chun ríomh an choimisiúin díolacháin a chur i gcrích in Excel. Déan mar seo a leanas le do thoil.
Céim 1: Cruthaigh Tábla Cuardaigh le haghaidh Gráid
Ar an gcéad dul síos, ní mór duit tábla cuardaigh a chruthú le haghaidh na ndíolachán agus an ráta coimisiúin comhfhreagrach, mar shampla E2:F4 sa chás seo. nótaí: Ní mór díolacháin sa chéad cholún den tábla a shórtáil in ord ardaitheach.
Céim 2: Cuir an fheidhm VLOOKUP i bhfeidhm chun gráid a shannadh
Roghnaigh ceall bán (C2 sa chás seo), cuir isteach an fhoirmle seo a leanas agus brúigh an eochair Enter chun an chéad choimisiún a fháil. Roghnaigh an chill fhoirmle seo agus tarraing a Fill Handle síos chun an chuid eile de na torthaí a fháil.
=B2*VLOOKUP(B2,$E$2:$F$4,2,TRUE)
- Sa dá shampla, úsáidtear VLOOKUP chun luach a fháil i dtábla atá bunaithe ar luach cuardaigh (scór nó méid díolacháin) agus cuireann sé luach sa tsraith chéanna ar ais ó cholún sonraithe (grád nó ráta coimisiúin). Léiríonn an ceathrú paraiméadar TRUE neasmheaitseáil, atá oiriúnach do na cásanna seo nuair nach mbeadh an luach cuardaigh beacht i láthair sa tábla.
- Chun tuilleadh eolais a fháil faoin bhfeidhm VLOOKUP, tabhair cuairt ar an leathanach seo.
Ag baint úsáide as IFS
An Feidhm IFS déanann sé an próiseas a shimpliú trí dheireadh a chur leis an ngá le neadú agus déanann sé na foirmlí níos éasca a léamh agus a bhainistiú. Feabhsaíonn sé inléiteacht agus sruthlíonn sé láimhseáil seiceálacha iolracha coinníollach. Chun feidhm IFS a úsáid, cinntigh go bhfuil Excel 2019 nó níos déanaí in úsáid agat, nó go bhfuil síntiús Office 365 agat. A ligean ar a fheiceáil conas is féidir é a chur i bhfeidhm i samplaí praiticiúla.
Sampla 1: Córas Grádaithe le IFS
Ag glacadh leis na critéir grádaithe chéanna is a bhí cheana, is féidir feidhm IFS a úsáid mar seo a leanas:
Roghnaigh ceall bán, mar shampla C2, cuir isteach an fhoirmle seo a leanas agus brúigh Iontráil chun an chéad toradh a fháil. Roghnaigh an chill toraidh seo agus tarraing a Líon Láimhseáil síos chun an chuid eile de na torthaí a fháil.
=IFS(B2>=90,"A",B2>=80,"B",B2>=70,"C",B2>=60,"D",B2<60,"F")
- Déantar gach coinníoll a mheas in ord. Chomh luath agus a chomhlíontar coinníoll, cuirtear a thoradh comhfhreagrach ar ais, agus stopann an fhoirmle ag seiceáil coinníollacha breise. Sa chás seo, úsáidtear an fhoirmle chun gráid a shannadh bunaithe ar an scór i B2, ag leanúint scála grádaithe tipiciúil nuair a fhreagraíonn scór níos airde do ghrád níos fearr.
- Chun tuilleadh eolais a fháil faoi fheidhm IFS, tabhair cuairt ar an leathanach seo.
Sampla 2: Ríomh an Choimisiúin Díolacháin le IFS
Maidir le cás ríomh an choimisiúin díolacháin, cuirtear feidhm IFS i bhfeidhm mar a leanas:
Roghnaigh ceall bán, mar shampla C2, cuir isteach an fhoirmle seo a leanas agus brúigh Iontráil chun an chéad toradh a fháil. Roghnaigh an chill toraidh seo agus tarraing a Líon Láimhseáil síos chun an chuid eile de na torthaí a fháil.
=B2*IFS(B2>20000,20%,B2>=10000,15%,TRUE,10%)
Ag baint úsáide as CHOOSE agus MATCH
Is féidir an cur chuige CHOOSE and MATCH a bheith níos éifeachtaí agus níos éasca a bhainistiú i gcomparáid le ráitis neadaithe IF. Déanann an modh seo an fhoirmle a shimpliú agus déanann sé nuashonruithe nó athruithe níos simplí. Thíos léireoidh mé conas meascán de na feidhmeanna CHOOSE agus MATCH a úsáid chun an dá shampla praiticiúla san Airteagal seo a láimhseáil.
Sampla 1: Córas Grádaithe le CHOOSE agus MATCH
Is féidir leat an teaglaim de na feidhmeanna CHOOSE agus MATCH a úsáid chun gráid a shannadh bunaithe ar scóir éagsúla.
Céim 1: Cruthaigh eagar Lookup le luachanna cuardaigh
Ar an gcéad dul síos, ní mór duit raon cealla a chruthú ina bhfuil na luachanna tairsí a ndéanfaidh MATCH cuardach orthu, mar $E$2:$E$6 sa chás seo. nótaí: Ní mór na huimhreacha sa raon seo a shórtáil in ord ardaitheach le go n-oibreoidh an fheidhm MATCH i gceart agus neaschineál meaitseála á úsáid.
Céim 2: Cuir CHOOSE agus MATCH i bhfeidhm chun gráid a shannadh
Roghnaigh ceall bán (C2 sa chás seo), cuir isteach an fhoirmle seo a leanas agus brúigh an Iontráil eochair chun an chéad ghrád a fháil. Roghnaigh an chill fhoirmle seo agus tarraing a Líon Láimhseáil síos chun an chuid eile de na torthaí a fháil.
=CHOOSE(MATCH(B2, $E$2:$E$6, 1), "F", "D", "C", "B", "A")
- MATCH(B2, $E$2:$E$6, 1): Féachann an chuid seo den fhoirmle an scór (95) i gcill B2 laistigh den raon $E$2:$E$6. Léiríonn an 1 gur cheart do MATCH neasmheaitseáil a aimsiú, rud a chiallaíonn go bhfaighidh sé an luach is mó sa raon atá níos lú ná nó cothrom le B2.
- CHOOSE(..., "F", "D", "C", "B", "A"): Bunaithe ar an seasamh ar ais ag an bhfeidhm MATCH, roghnaíonn CHOOSE grád comhfhreagrach.
- Níos mó eolais a fháil ar an Feidhm MATCH, tabhair cuairt ar an leathanach seo.
- Níos mó eolais a fháil ar an ROGHA feidhm, tabhair cuairt ar an leathanach seo.
Sampla 2: Ríomh an Choimisiúin Díolacháin le IFS
Is féidir úsáid a bhaint as teaglaim CHOOSE agus MATCH le haghaidh Ríomh ón gCoimisiún Díolacháin a bheith éifeachtach freisin, go háirithe nuair a bhíonn na rátaí coimisiúin bunaithe ar thairseacha sonraithe díolacháin. A ligean ar a fheiceáil conas is féidir linn a dhéanamh.
Céim 1: Cruthaigh eagar Lookup le luachanna cuardaigh
Ar an gcéad dul síos, ní mór duit raon cealla a chruthú ina bhfuil na luachanna tairsí a ndéanfaidh MATCH cuardach orthu, mar $E$2:$E$4 sa chás seo. nótaí: Ní mór na huimhreacha sa raon seo a shórtáil in ord ardaitheach le go n-oibreoidh an fheidhm MATCH i gceart agus neaschineál meaitseála á úsáid.
Céim 2: Cuir CHOOSE agus MATCH i bhfeidhm chun na torthaí a fháil
Roghnaigh ceall bán (C2 sa chás seo), cuir isteach an fhoirmle seo a leanas agus brúigh an Iontráil eochair chun an chéad ghrád a fháil. Roghnaigh an chill fhoirmle seo agus tarraing a Líon Láimhseáil síos chun an chuid eile de na torthaí a fháil.
=B2*CHOOSE(MATCH(B2, $E$2:$E$4, 1), 10%, 15%, 20%)
- Níos mó eolais a fháil ar an Feidhm MATCH, tabhair cuairt ar an leathanach seo.
- Níos mó eolais a fháil ar an ROGHA feidhm, tabhair cuairt ar an leathanach seo.
Mar fhocal scoir, is scil luachmhar é máistreacht a dhéanamh ar ráitis IF neadaithe in Excel a fheabhsaíonn do chumas cásanna casta loighciúla a láimhseáil i bpróisis anailíse sonraí agus cinnteoireachta. Cé go bhfuil IFanna neadaithe cumhachtach le haghaidh oibríochtaí casta loighciúla, tá sé tábhachtach a bheith san airdeall ar a dteorainneacha. Is féidir le roghanna eile níos simplí cosúil le VLOOKUP, IFS, agus CHOOSE le MATCH réitigh níos sruthlínithe a sholáthar i gcásanna áirithe. Agus na léargais seo agat, is féidir leat anois na teicnící Excel is oiriúnaí a chur i bhfeidhm go muiníneach ar do thascanna anailíse sonraí, ag cinntiú soiléireacht, cruinneas agus éifeachtúlacht i do scarbhileoga. Dóibh siúd a bhfuil fonn orthu dul i mbun inniúlachta Excel, tá neart ranganna teagaisc ar ár suíomh Gréasáin. Faigh amach tuilleadh leideanna agus cleasanna Excel anseo.
Uirlisí Táirgiúlachta Oifige is Fearr
Supercharge Do Scileanna Excel le Kutools le haghaidh Excel, agus Éifeachtúlacht Taithí Cosúil Ná Roimhe. Kutools le haghaidh Excel Tairiscintí Níos mó ná 300 Ardghnéithe chun Táirgiúlacht a Treisiú agus Sábháil Am. Cliceáil anseo chun an ghné is mó a theastaíonn uait a fháil ...
Tugann Tab Oifige comhéadan Tabbed chuig Office, agus Déan Do Obair i bhfad Níos Éasca
- Cumasaigh eagarthóireacht agus léamh tabbed i Word, Excel, PowerPoint, Foilsitheoir, Rochtain, Visio agus Tionscadal.
- Oscail agus cruthaigh cáipéisí iolracha i gcluaisíní nua den fhuinneog chéanna, seachas i bhfuinneoga nua.
- Méadaíonn do tháirgiúlacht 50%, agus laghdaíonn sé na céadta cad a tharlaíonn nuair luch duit gach lá!
Clár ábhair
- MÁ feidhm vs. Ráitis IF Neadaithe
- Úsáid neadaithe IF
- Comhréir na neadaithe IF
- Samplaí praiticiúla de neadaithe IF
- Neadaithe má tá riocht AGUS / OR
- Leideanna agus cleasanna le haghaidh neadaithe IF
- Ag déanamh neadaithe MÁ éasca é a léamh
- Ord na bhfeidhmeanna IF neadaithe
- Ba cheart caitheamh go héagsúil le huimhreacha agus le téacs
- Teorainneacha neadaithe MÁS
- Roghanna eile seachas Nested IF
- Ag baint úsáide as VLOOKUP
- Ag baint úsáide as IFS
- Ag baint úsáide as CHOOSE agus MATCH
- Airteagail gaolmhara
- Na hUirlisí Táirgiúlachta Oifige is Fearr
- Comments