Excel CHOOSE fheidhm

Tuairisc

Comhréir agus Argóintí

Úsáid agus Samplaí

• Ex1 - Úsáid bhunúsach: ag úsáid CHOOSE feidhmiú ina n-aonar chun luach a roghnú as argóint liosta
• Ex2 - Torthaí difriúla a thabhairt ar ais bunaithe ar ilchoinníollacha
• Ex3 - Torthaí ríofa difriúla a thabhairt ar ais bunaithe ar choinníollacha
• Ex4 - Roghnaigh randamach ón liosta
• Ex5 - Comhcheangail CHOOSE agus VLOOKUP feidhmeanna chun luach a thabhairt ar ais sa cholún ar chlé
• Ex6 - Fill ar ais i rith na seachtaine nó na míosa bunaithe ar an dáta áirithe
• Ex7 - Fill ar ais go dtí an chéad dáta oibre / deireadh seachtaine eile bunaithe ar an lá inniu

Tuairisc

An CHOOSE filleann feidhm luach ón liosta argóintí luacha bunaithe ar an uimhir innéacs tugtha. Mar shampla, CHOOSE(3,”Apple”,”Peach”,”Orange”) filleann Orange, is é 3 an uimhir innéacs, agus is é Orange an tríú luach i ndiaidh uimhir innéacs san fheidhm.

comhréir agus Argóintí

Comhréir na foirmle

Argóintí

Value1, value2… Is féidir uimhreacha, téacsanna, foirmlí, tagairtí cille, nó ainm sainithe a bheith iontu.

Luach Tuairisceáin

An CHOOSE filleann feidhm luach ó liosta bunaithe ar an suíomh ar leith.

Úsáid agus Samplaí

Sa chuid seo, liostálann mé roinnt samplaí simplí ach ionadaíocha chun úsáid an CHOOSE fheidhm.

Ex1 - Úsáid bhunúsach: ag úsáid CHOOSE feidhmiú ina n-aonar chun luach a roghnú as argóint liosta

Foirmle1:

=CHOOSE(3,"a","b","c","d")

Tuairisceán: c, arb é an tríú argóint é tar éis an index_num de 3 sa CHOOSE fheidhm.

Nóta: luachana dúbailte a úsáid a bhaineann leis an luach más téacs é.

Foirmle2:

=CHOOSE(2,A1,A2,A3,A4)

Tuairisceán: Kate, luach A2. Ós rud é gurb é 2 an index_num, agus gurb é A2 an dara luach sa CHOOSE fheidhm.

Foirmle3:

=CHOOSE(4,8,9,7,6)

Fill ar ais: 6, argóint an 4ú liosta san fheidhm.

Ex2 - Torthaí difriúla a thabhairt ar ais bunaithe ar ilchoinníollacha

Má cheaptar go bhfuil liosta diall agat do gach táirge ba ghá a lipéadú bunaithe ar dhálaí mar a thaispeántar thíos an pictiúr.

De ghnáth, is féidir leat an fheidhm IF a úsáid chun láimhseáil, ach anseo tugaim isteach conas an CHOOSE feidhm chun an fhadhb seo a réiteach go héasca

Foirmle:

=CHOOSE((B7>0)+(B7>1)+(B7>5),"Top","Middle","Bottom")

Mínigh:

(B7>0)+(B7>1)+(B7>5): is é 7 an index_num, B2, atá níos mó ná 0 agus 1 ach níos lú ná 5, agus mar sin faighimid an toradh idirmheánach:

=CHOOSE(True+Ture+False,"Top","Middle","Bottom")

Mar is eol dúinn, Fíor = 1, Bréagach = 0, mar sin is féidir féachaint ar an bhfoirmle mar:

=CHOOSE(1+1+0,"Top","Middle","Bottom")

ansin

=CHOOSE(2,"Top","Middle","Bottom")

Toradh: Meán

Ex3 - Torthaí ríofa difriúla a thabhairt ar ais bunaithe ar choinníollacha

Má cheaptar go gcaithfidh tú na lacáistí do gach táirge a ríomh bunaithe ar an méid agus an praghas mar atá thíos ar an scáileán a thaispeántar:

Foirmle:

=CHOOSE((B8>0)+(B8>100)+(B8>200)+(B8>300),B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

Mínigh:

(B8>0)+(B8>100)+(B8>200)+(B8>300): index_number, B8 is 102, atá níos mó ná 100 ach níos lú ná 201, mar sin sa chuid seo, filleann sé an toradh a thaispeántar mar:

=CHOOSE(true+true+false+false,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

=CHOOSE(1+1+0+0,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

ansin

=CHOOSE(2,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5: is ionann na luachanna le roghnú, lacáiste agus praghas * méid * lacáiste faoin gcéad, ós rud é gurb é index_num 2, roghnaíonn sé B8 * C8 * 0.2

Tuairisceáin: 102 * 2 * 0.2 = 40.8

Ex4 - Roghnaigh randamach ón liosta

In Excel, uaireanta, b’fhéidir go mbeidh ort luach a roghnú go randamach ó liosta ar leith, an CHOOSE is féidir le feidhm an post seo a réiteach.

Roghnaigh luach amháin go randamach as liosta:

Foirmle:

=CHOOSE(RANDBETWEEN(1,5),$D$2,$D$3,$D$4,$D$5,$D$6)

Mínigh:

RANDBETWEEN(1,5): index_num, faigh uimhir go randamach idir 1 agus 5

$D$2,$D$3,$D$4,$D$5,$D$6: liosta na luachanna le roghnú as

Ex5 - Comhcheangail CHOOSE agus VLOOKUP feidhmeanna chun luach a thabhairt ar ais sa cholún ar chlé

Go ginearálta, úsáidimid an fheidhm VLOOKUP =VLOOKUP (value, table, col_index, [range_lookup]) luach a thabhairt ar ais bunaithe ar luach ar leith ó raon tábla. Ach leis an VLOOKUP feidhm, tabharfaidh sé luach earráide ar ais fad a bheidh an colún tuairisceáin ar thaobh na láimhe clé den cholún lookup mar atá thíos an pictiúr a thaispeántar:

Sa chás seo, is féidir leat an CHOOSE feidhm le feidhm VLOOKUP chun an fhadhb a réiteach.

Foirmle:

=VLOOKUP(E1,CHOOSE({1,2},B1:B7,A1:A7),2,FALSE)

Mínigh:

CHOOSE({1,2},B1:B7,A1:A7): mar argóint table_range i bhfeidhm VLOOKUP. Ciallaíonn {1,2} 1 nó 2 a thaispeáint mar argóint index_num bunaithe ar an argóint col_num i bhfeidhm VLOOKUP. Anseo, is é 2 an fheidhm col_num i VLOOKUP, mar sin an CHOOSE taispeáint feidhm mar CHOOSE(2, B1:B7,A1:A7), ciallaíonn sé luach a roghnú as A1: A7.

Ex6 - Fill ar ais i rith na seachtaine nó na míosa bunaithe ar an dáta áirithe

Leis an CHOOSE feidhm, is féidir leat an lá agus an mhí coibhneasta seachtaine a thabhairt ar ais bunaithe ar dháta faoi leith.

Foirmle 1: filleadh lá na seachtaine faoi dháta

=CHOOSE(WEEKDAY(),"Sunday","Monday","Tuesday","Wednesday","Thursday","Friday","Saturday")

Mínigh:

WEEKDAY(): an argóint index_num, chun uimhir lae na seachtaine den dáta áirithe a fháil, mar shampla, tuairisceáin SEACHTAINIÚIL (A5) 6, ansin is í an argóint index_num ná 6.

"Sunday","Monday","Tuesday","Wednesday","Thursday","Friday","Saturday": argóintí ar liosta luacha, tosaigh le “Dé Domhnaigh” toisc go léiríonn uimhir na seachtaine “1” “Dé Domhnaigh”.

Foirmle 2: mí ar ais faoi dháta

=CHOOSE(MONTH(),"Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")

Mínigh:

MONTH(): argóint index_num, a fhaigheann uimhir na míosa ón dáta áirithe, mar shampla, MONTH (A5) tuairisceáin 3.

Ex7 - Fill ar ais go dtí an chéad dáta oibre / deireadh seachtaine eile bunaithe ar an lá inniu

San obair laethúil, b’fhéidir gur mhaith leat an chéad lá oibre nó deireadh seachtaine eile a ríomh bunaithe ar an lá inniu. Seo an CHOOSE is féidir le feidhm fabhar a dhéanamh duit freisin.

Mar shampla, inniu is é 12/20/2018, Déardaoin, anois ní mór duit an chéad lá oibre agus deireadh seachtaine eile a fháil.

Foirmle 1: faigh dáta an lae inniu

=TODAY()

Toradh: 12/20/2018

Foirmle 2: faigh uimhir na seachtaine inniu

=WEEKDAY(TODAY())

Toradh: 5 (cé gurb é inniu 12/20/2018)

Taispeántar liosta uimhreacha i rith na seachtaine mar atá thíos ar an scáileán:

Foirmle 3: faigh an chéad lá oibre eile

=TODAY()+CHOOSE(WEEKDAY(TODAY()),1,1,1,1,1,3,2)

Mínigh:

Today(): cuir an dáta reatha ar ais

WEEKDAY(TODAY()): argóint index_num san CHOOSE feidhm, faigh uimhir lae na seachtaine inniu, mar shampla, is é an Domhnach 1, is é Dé Luain 2…

1,1,1,1,1,3,2: argóint liosta luacha sa CHOOSE feidhm. Mar shampla, má fhilleann lá na seachtaine (inniu ()) 1 (Dé Domhnaigh), roghnaíonn sé 1 foirm an liosta luachanna, ansin athraíonn an fhoirmle iomlán go = Inniu () + 1, rud a chiallaíonn 1 lá a chur le filleadh Dé Luain seo chugainn. Má fhilleann lá na seachtaine (inniu ()) 6 (Dé hAoine), roghnaíonn sé 3 ón liosta luachanna, toisc go bhfuil an Aoine 3 lá i bhfad ón Luan seo chugainn.

Toradh (cé gurb é 12/20/2018 inniu):

=12/20/2018+CHOOSE(5,1,1,1,1,1,3,2)

= 12/20/2018 + 1

= 12/21/2018

Foirmle 4: a fháil an lá deireadh seachtaine dár gcionn

=TODAY()+CHOOSE(WEEKDAY(TODAY()),6,5,4,3,2,1,1)

Mínigh:

6,5,4,3,2,1,1: argóint liosta luacha sa CHOOSE feidhm. Mar shampla, má fhilleann lá na seachtaine (inniu ()) 1 (Dé Domhnaigh), roghnaíonn sé 6 ón liosta luachanna, ansin athraíonn an fhoirmle iomlán go = Inniu () + 6, rud a chiallaíonn 6 lá a chur leis agus filleadh Dé Sathairn seo chugainn.

Toradh:

=12/20/2018+CHOOSE(5,6,5,4,3,2,1,1)

= 12/20/2018 + 2

= 12/22/2018

Comhad Samplach