Conas ríomhphoist a bhratach go huathoibríoch bunaithe ar cheangaltán sonrach le dearcadh?

Nuair a fhaigheann tú roinnt ríomhphoist a bhfuil ceangaltán tábhachtach sonrach acu, b’fhéidir go mbeidh ort iad a bhratach, ionas gur féidir leat iad a aimsiú go tapa agus go héasca le haghaidh sreabhadh suas. Labhróidh mé san alt seo faoi bhealach éasca chun na ríomhphoist a ghabhann le ceangaltáin le hainmneacha ar leith a bhratach go huathoibríoch.

Cuir bratach go huathoibríoch ar ríomhphoist bunaithe ar cheangaltán sonrach le cód VBA

Cuir bratach go huathoibríoch ar ríomhphoist bunaithe ar cheangaltán sonrach le cód VBA

Chun na ríomhphoist a bhfuil an ceangaltán sonrach iontu a bhratach go huathoibríoch, cuir an cód VBA seo a leanas i bhfeidhm:

1. Seoladh an Outlook, agus ansin coinnigh síos an ALT + F11 eochracha a oscailt Microsoft Visual Basic d’Fheidhmchláir fhuinneog.

2. Sa an Microsoft Visual Basic d’Fheidhmchláir fuinneog, cliceáil dúbailte ThisOutlookSession ó na Tionscadal1 (VbaProject.OTM) pane chun modh nua a oscailt, agus ansin cóipeáil agus greamaigh an cód seo a leanas isteach sa mhodúl bán.

Cód VBA: Cuir bratach go huathoibríoch ar na ríomhphoist bunaithe ar cheangaltán sonrach:

Public WithEvents GMailItems As Outlook.Items
Private Sub Application_Startup()
    Set GMailItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub GMailItems_ItemAdd(ByVal Item As Object)
    If Item.Class <> olMail Then Exit Sub
    FlagEmail_SpecificAttachments Item
End Sub

Sub FlagEmail_SpecificAttachments(Mail As Outlook.MailItem)
    Dim xAttachment As Outlook.Attachment
    Dim xExt As String
    Dim xFileName As String
    If Mail.Attachments.Count = 0 Then Exit Sub
    For Each xAttachment In Mail.Attachments
        xExt = SplitPath(xAttachment.FileName, 2)
        xFileName = SplitPath(xAttachment.FileName, 1)
        Select Case xExt
            Case "txt", "xlsx", "docx", "pdf"  'Add the file extension as you need
                If InStr(LCase(xFileName), LCase("KTO")) > 0 Then 'Change the text of the attachment name
                    With Mail
                        .ReminderSet = True
                        .ReminderTime = Now + 1
                        .MarkAsTask olMarkTomorrow
                        .Save
                    End With
                End If
        End Select
    Next
End Sub

Public Function SplitPath(FullPath As String, ResultFlag As Integer) As String
Dim xSplitPos As Integer, xDotPos As Integer
xSplitPos = InStrRev(FullPath, "/")
xDotPos = InStrRev(FullPath, ".")
Select Case ResultFlag
    Case 0
        SplitPath = Left(FullPath, xSplitPos - 1)
    Case 1
        If xDotPos = 0 Then xDotPos = Len(FullPath) + 1
        SplitPath = Mid(FullPath, xSplitPos + 1, xDotPos - xSplitPos - 1)
    Case 2
        If xDotPos = 0 Then xDotPos = Len(FullPath)
        SplitPath = Mid(FullPath, xDotPos + 1)
    Case Else
    Err.Raise vbObjectError + 1, "SplitPath Function", "Invalid Parameter!"
End Select
End Function

nótaí: Sa chód thuas, is féidir leat an síneadh comhad agus ainm an chomhaid ceangaltáin a athrú go dtí do riachtanas.

3. Ansin sábháil an cód, agus atosaigh an Outlook chun an cód a chur i bhfeidhm, anois, nuair a fhaigheann tú na ríomhphoist ina bhfuil an téacs sonraithe in ainmneacha na gceangaltán, cuirfidh Outlook bratach uathoibríoch ar an ríomhphost seo le haghaidh obair leantach, féach an scáileán: