Conas cruinnithe seolta a aistriú go huathoibríoch chuig fillteán ar leith in Outlook?

De ghnáth, tar éis na ríomhphoist nó na cruinnithe a sheoladh, beidh an bheirt acu lonnaithe san fhillteán Míreanna Seolta. Mar sin, beidh an fillteán Míreanna Seolta an-fhabhrach agus an-deacair. An t-alt seo, tabharfaidh mé modh isteach chun na cruinnithe seolta a aistriú go fillteán eile go huathoibríoch tar éis an cruinniú a sheoladh amach.

Bog na cruinnithe seolta go huathoibríoch chuig fillteán ar leith le cód VBA

Bog na cruinnithe seolta go huathoibríoch chuig fillteán ar leith le cód VBA

Chun gach cuireadh cruinnithe a sheoltar a aistriú go fillteán eile go huathoibríoch, is féidir leis an gcód seo a leanas cabhrú leat, déan é seo le do thoil:

1. Coinnigh síos an ALT + F11 eochracha a oscailt Microsoft Visual Basic d’Fheidhmchláir fhuinneog.

2. Sa an Microsoft Visual Basic d’Fheidhmchláir fuinneog, cliceáil dúbailte ThisOutlookSession ó na Tionscadal1 (VbaProject.OTM) pána chun an modh a oscailt, agus ansin an cód seo a leanas a chóipeáil agus a ghreamú isteach sa mhodúl bán.

Cód VBA: Bog na cruinnithe seolta go huathoibríoch chuig fillteán ar leith

Private WithEvents GExplorer As Outlook.Explorer
Public WithEvents GSentFolder As Outlook.Folder
Public WithEvents GSentItems As Outlook.Items
Private Sub Application_Startup()
    Set GExplorer = Outlook.Application.ActiveExplorer
End Sub
Private Sub GExplorer_SelectionChange()
Dim xFolder As Folder, xRootFolder As Folder
Dim xRootFldName As String
Dim xPos As Integer
    On Error Resume Next
    Set xFolder = Outlook.Application.ActiveExplorer.CurrentFolder
    xPos = VBA.InStr(3, xFolder.FolderPath, "\")
    If xPos > 0 Then
        xRootFldName = VBA.Mid(xFolder.FolderPath, 3, xPos - 3)
    Else
        xRootFldName = VBA.Mid(xFolder.FolderPath, 3, Len(xFolder.FolderPath) - 2)
    End If
    Set xRootFolder = Outlook.Application.Session.Folders(xRootFldName)
    Set GSentFolder = xRootFolder.Folders("Sent Items")
    Set GSentItems = GSentFolder.Items
End Sub
Private Sub GSentItems_ItemAdd(ByVal Item As Object)
    Dim xMeetingItem As Outlook.MeetingItem
    Dim xTargetFolder As Outlook.Folder
    On Error Resume Next
    If Item.Class <> olMeetingRequest Then Exit Sub
    Set xMeetingItem = Item
    Set xTargetFolder = GSentFolder.Folders("Meetings")
    If xTargetFolder Is Nothing Then
        Set xTargetFolder = GSentFolder.Folders.Add("Meetings")
    End If
    xMeetingItem.Move xTargetFolder
End Sub

seoladh seolta seolta 1

3. Ansin, sábháil agus dún an fhuinneog cód. Anois, nuair a sheolfar r-phost cruinnithe, bogfar é chuig fillteán nua darb ainm Cruinnithe faoi na Míreanna Seolta fillteán go huathoibríoch, féach an scáileán:

seoladh seolta seolta 2