Outlook: Conas cruinniú cealaithe a choinneáil i bhféilire mar eagraí?

In Outlook, mar eagraí cruinnithe, nuair a chuireann tú an cruinniú ar ceal, scriosfar an cruinniú go huathoibríoch ón bhféilire. I gcásanna áirithe, b’fhéidir gur mhaith leat na cruinnithe cealaithe a choinneáil san fhéilire chun roinnt marcanna a dhéanamh. Mar sin féin, níl aon ghnéithe ionsuite in Outlook ar féidir leo an post seo a láimhseáil. Sa rang teagaisc seo, soláthraíonn sé dhá chód VBA chun an cruinniú a choinneáil mar choinne agus é ar ceal.

Cóid VBA chun cruinniú cealaithe a chóipeáil mar choinne

---

Cóid VBA chun cruinniú cealaithe a chóipeáil mar choinne

Seo dhá chód chun an cruinniú a chur ar ceal agus é a chóipeáil agus a ghreamú mar choinne ag an am céanna.

Tabhair faoi deara: sula ndéanann tú an cód a chumasú, déan cinnte go ndéantar an dá rogha seo a sheiceáil:

Cumasaigh Outlook, cliceáil Comhad > Roghanna, i bhfuinneog Roghanna Outlook, cliceáil Ionad Iontaobhas cluaisín, agus cliceáil Socruithe Ionad Iontaobhais, ansin i bhfuinneog an Ionaid Iontaobhais, cliceáil Socruithe Macra tab, seiceáil Cumasaigh gach macraí (ní mholtar; is féidir cód a d’fhéadfadh a bheith contúirteach a rith) agus Cuir socruithe slándála macra ar bhreiseáin suiteáilte roghanna. Cliceáil OK > OK na fuinneoga a dhúnadh. Atosaigh Ionchas.

1. Swift go Outlook Calendar view, agus roghnaigh an cruinniú gur mian leat Brúigh a chur ar ceal Eile + F11 eochracha chun an fhuinneog Microsoft Visual Basic for Applications a chumasú.

2. cliceáil Ionsáigh > Modúil chun modúl bán nua a chur isteach. Ansin cóipeáil agus greamaigh an cód thíos leis.

Cód: Cóipeáil cruinniú mar choinne agus cuir ar ceal é

Sub CopyMeetingAsAppointmentBeforeCancel()
'UpdatebyExtendoffice20221129
Dim xAppointmentItem As AppointmentItem
Dim xMeetingItem As AppointmentItem
On Error Resume Next
Set xMeetingItem = GetCurrentItem()
Set xAppointmentItem = Application.CreateItem(olAppointmentItem)
With xAppointmentItem
  .Subject = "Canceled: " & xMeetingItem.Subject
  .Start = xMeetingItem.Start
  .Duration = xMeetingItem.Duration
  .Location = xMeetingItem.Location
  .Body = xMeetingItem.Body
  .Save
  .Move Application.ActiveExplorer.CurrentFolder
End With
With xMeetingItem
  .MeetingStatus = olMeetingCanceled
  .Send
  .Delete
End With
Set xAppointmentItem = Nothing
Set xMeetingItem = Nothing
End Sub

Function GetCurrentItem() As Object
  On Error Resume Next
  Select Case TypeName(Application.ActiveWindow)
    Case "Explorer"
      Set GetCurrentItem = Application.ActiveExplorer.Selection.Item(1)
    Case "Inspector"
      Set GetCurrentItem = Application.ActiveInspector.CurrentItem
  End Select
End Function

3. cliceáil Rith cnaipe nó brúigh F5 eochair, anois tá an cruinniú roghnaithe curtha ar ceal agus coinne nua darb ainm Cancled & subjet.

Más mian leat an cruinniú a chóipeáil agus a ghreamú mar choinne i bhféilire eile agus ansin an cruinniú a chur ar ceal, bain úsáid as an gcód thíos:

Cód: Cóipeáil cruinniú mar choinne i bhféilire eile agus cuir ar ceal é

Sub CopyMeetingAsAppointmentToCalenderBeforeCancel()
'Updatebyextendoffice20221129
Dim xDestCalendar As Outlook.MAPIFolder
Dim xNameSpace As Outlook.NameSpace
Dim xAppointmentItem As AppointmentItem
Dim xMeetingItem As AppointmentItem
On Error Resume Next
Set xNameSpace = Application.GetNamespace("MAPI")
Set xDestCalendar = xNameSpace.PickFolder
If xDestCalendar.DefaultItemType <> olAppointmentItem Then
  MsgBox "Please Select calendar folder. ", vbOKOnly + vbInformation, "Kutools for Outlook"
  Exit Sub
End If
Set xMeetingItem = GetCurrentItem()
Set xAppointmentItem = Application.CreateItem(olAppointmentItem)
With xAppointmentItem
  .Subject = "Canceled: " & xMeetingItem.Subject
  .Start = xMeetingItem.Start
  .Duration = xMeetingItem.Duration
  .Location = xMeetingItem.Location
  .Body = xMeetingItem.Body
  .Save
  .Move xDestCalendar
End With
With xMeetingItem
  .MeetingStatus = olMeetingCanceled
  .Send
  .Delete
End With
Set xDestCalendar = Nothing
Set xNameSpace = Nothing
Set xAppointmentItem = Nothing
Set xMeetingItem = Nothing
End Sub

Function GetCurrentItem() As Object
  On Error Resume Next
  Select Case TypeName(Application.ActiveWindow)
    Case "Explorer"
      Set GetCurrentItem = Application.ActiveExplorer.Selection.Item(1)
    Case "Inspector"
      Set GetCurrentItem = Application.ActiveInspector.CurrentItem
  End Select
End Function

cliceáil Rith cnaipe nó brúigh F5 eochair, a Roghnaigh Fillteán dialóg pop amach chun tú a roghnú fillteán féilire chun an ceapachán a ghreamú, ansin cliceáil OK.

Anois tá an cruinniú curtha ar ceal agus é a chóipeáil agus a ghreamú mar choinne san fhillteán féilire a roghnaíonn tú.