Conas féilire a sheoladh chuig iliomad faighteoirí ina n-aonar in Outlook?

De ghnáth, is féidir leat féilire a sheoladh chuig faighteoir go tapa agus go héasca trí úsáid a bhaint as an Féilire R-phoist gné in Outlook. Más mian leat féilire atá ceangailte mar chomhad iCalendar a sheoladh chuig teagmhálacha iolracha ina n-aonar, ní mór duit é a sheoladh ceann ar cheann. San Airteagal seo, labhróidh mé faoi bhealach éasca le féilire a sheoladh chuig iliomad faighteoirí ina n-aonar in Outlook.

Seol féilire chuig faighteoirí iolracha ina n-aonar le cód VBA

Seol féilire chuig faighteoirí iolracha ina n-aonar le cód VBA

Chun féilire a sheoladh chuig iliomad faighteoirí ar leithligh, is féidir leis an gcód VBA seo a leanas cabhrú leat, déan é seo le do thoil:

1. Téigh go dtí an Teagmhálacha pána, agus roghnaigh na teagmhálacha ar mhaith leat féilire a sheoladh chucu.

2. Ansin coinnigh síos an ALT + F11 eochracha a oscailt Microsoft Visual Basic d’Fheidhmchláir fhuinneog.

3. Cliceáil Ionsáigh > Modúil, cóipeáil agus greamaigh an cód thíos sa mhodúl bán oscailte, féach an pictiúr:

Cód VBA: Seol féilire chuig faighteoirí iolracha ina n-aonar ：

Sub EmailCalendarToMultiplePersonsSeparately()
Dim xSelection As Outlook.Selection
Dim xCalendarFolder As Outlook.Folder
Dim xCalendarExporter As Outlook.CalendarSharing
Dim xStartDate, xEndDate As Date
Dim xCalendarFile As String
Dim xContactItem As Outlook.ContactItem
Dim xDistListItem As Outlook.DistListItem
Dim xItem As Object
Dim xMailItem As Outlook.MailItem
Dim xFilePath, xFileName, xEmailAddress As String
Dim xRecipient As Recipient
On Error Resume Next
xFilePath = CreateObject("WScript.Shell").SpecialFolders(16) & "\MyCalendar"
If Dir(xFilePath, vbDirectory) = "" Then MkDir xFilePath
If Outlook.Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olContactItem Then
    MsgBox "Please Select contacts first!", vbExclamation + vbOKOnly, "Kutools for Outlook"
    Exit Sub
End If
Set xSelection = Outlook.Application.ActiveExplorer.Selection
If xSelection Is Nothing Then Exit Sub
Set xCalendarFolder = Outlook.Application.Session.PickFolder
If xCalendarFolder Is Nothing Then Exit Sub
If xCalendarFolder.DefaultItemType <> olAppointmentItem Then Exit Sub
Set xCalendarExporter = xCalendarFolder.GetCalendarExporter
xStartDate = InputBox("Enter the start date:", "Kutools for Outlook", "")
If Len(Trim(xStartDate)) = 0 Then Exit Sub
xEndDate = InputBox("Enter the end date:", "Kutools for Outlook", "")
If Len(Trim(xEndDate)) = 0 Then Exit Sub
If xStartDate = #1/1/4501# Or xEndDate = #1/1/4501# Then Exit Sub
xFileName = "Calendar (" & Format(xStartDate, "YYYYMMDD") & " - " & Format(xEndDate, "YYYYMMDD") & ").ics"
xCalendarFile = xFilePath & "\" & xFileName
With xCalendarExporter
    .IncludeWholeCalendar = False
    .StartDate = xStartDate
    .EndDate = xEndDate
    .CalendarDetail = olFullDetails
    .IncludeAttachments = True
    .IncludePrivateDetails = False
    .RestrictToWorkingHours = False
    .SaveAsICal xCalendarFile
End With
For Each xItem In xSelection
    If xItem.Class = olContact Then
        Set xContactItem = xItem
        Set xMailItem = Outlook.Application.CreateItem(olMailItem)
        With xMailItem
            .To = xContactItem.Email1Address
            .Recipients.ResolveAll
            .Subject = xFileName
            .Attachments.Add xCalendarFile
            .Body = "Dear " & xContactItem.FullName & "," & vbCrLf & "Type body here..."
            .Display
        End With
    End If
    If xItem.Class = olDistributionList Then
        Set xDistListItem = xItem
        For i = 1 To xDistListItem.MemberCount
            Set xRecipient = xDistListItem.GetMember(i)
            Set xMailItem = Outlook.Application.CreateItem(olMailItem)
            With xMailItem
                .To = xRecipient.AddressEntry.Address
                .Recipients.ResolveAll
                .Subject = xFileName
                .Attachments.Add xCalendarFile
                .Body = "Dear " & xRecipient.Name & "," & vbCrLf & "Type body here..."
                .Display
            End With
        Next i
    End If
Next
End Sub

4. Tar éis duit an cód a chur isteach, ansin brúigh F5 eochair chun an cód seo a rith, agus a Roghnaigh Fillteán tá bosca dialóige popped amach, roghnaigh féilire is mian leat a sheoladh, féach screenshot:

5. cliceáil OK, agus ansin sonraigh an raon dáta ar mhaith leat an féilire a sheoladh sna boscaí pras seo a leanas, féach an pictiúr:

6. Agus ansin, cliceáil OK, cruthaíodh ríomhphoist nua le féilire ceangailte mar a thaispeántar an scáileán a leanas, ansin ní gá duit ach iad a sheoladh ceann ar cheann.