Sliocht gach focal ach an chéad cheann nó an ceann deireanach as cill in Excel
Sa rang teagaisc seo, foghlaimeoimid conas foirmlí a úsáid chun gach focal a bhaint as cill seachas an chéad cheann nó an ceann deireanach in Excel.
Sliocht gach focal ach ar dtús ó chill in Excel
Sliocht gach focal ach maireann sé ó chill in Excel
Sliocht gach focal ach ar dtús ó chill in Excel
Mar a thaispeántar an pictiúr thíos, ba mhaith leat gach focal a bhaint as gach cill i gcolún B seachas an chéad cheann, is féidir leat teaglaim de na feidhmeanna CEART, LEN agus FIND a úsáid chun é a bhaint amach. Déan mar a leanas le do thoil.
Foirmle cineálach
=RIGHT(text_string,LEN(text_string)-FIND(" ",text_string,1))
Argóintí
Teaghrán_téacs: An téad téacs a bhainfidh tú gach focal uaidh seachas an chéad cheann. Is féidir é a bheith:
- Teaghrán an téacs faoi iamh le comharthaí athfhriotail;
- Nó tagairt do chillín ina bhfuil an sreangán téacs.
Conas an fhoirmle seo a úsáid?
1. Roghnaigh cill bhán chun na focail eastósctha a aschur. Sa chás seo, roghnaigh mé cill D3.
2. Iontráil an fhoirmle thíos inti agus brúigh an Iontráil eochair. Agus ansin roghnaigh agus tarraing an chill fhoirmle an bealach ar fad síos chun í a chur i bhfeidhm ar chealla eile.
=RIGHT(B3,LEN(B3)-FIND(" ",B3,1))
Anois baintear gach focal i gcealla ar leith seachas na chéad fhocail.
nótaí: San fhoirmle thuas, is é B3 an chill ina bhfuil na focail a bhainfidh tú amach seachas an chéad cheann. Athraigh é le do thoil bunaithe ar do riachtanas.
Conas a oibríonn an fhoirmle seo?
=RIGHT(B3,LEN(B3)-FIND(" ",B3,1))
1. LEN(B3): Ríomhann feidhm LEN fad iomlán an bhreiseáin áisiúil Excel agus tugtar an toradh ar ais mar 17;
2. FIND(" ",B3,1): De réir mar a bhíonn na focail scartha de réir spáis, aimsíonn an fheidhm FIND suíomh an chéad spáis in Excel handy addin agus cuireann sé an toradh ar ais mar 6;
3. RIGHT(B3,17-6): Baineann an fheidhm CEART 11 carachtar (17-6 = 11) ón taobh deas den téad téacs "Excel handy addin". Is é an toradh "handy addin".
Sliocht gach focal ach maireann sé ó chill in Excel
Sa chuid seo, táimid chun teaglaim de na feidhmeanna LEFT, FIND, SUBSTITUTE agus LEN a úsáid chun gach focal seachas an ceann deireanach a bhaint as cill ar leith in Excel.
Foirmle cineálach
=LEFT(text_string,FIND("[",SUBSTITUTE(text_string," ","[",LEN(text_string)-LEN(SUBSTITUTE(text_string," ",""))))-1)
Argóintí
Teaghrán_téacs: An téad téacs a bhainfidh tú gach focal uaidh seachas an ceann deireanach. Is féidir é a bheith:
- Teaghrán an téacs faoi iamh le comharthaí athfhriotail;
- Nó tagairt do chillín ina bhfuil an sreangán téacs.
Conas an fhoirmle seo a úsáid?
1. Roghnaigh cill bhán (mar D3 sa chás seo) chun na focail eastósctha a aschur.
2. Iontráil an fhoirmle thíos inti agus brúigh an Iontráil eochair. Agus ansin tarraing an chill fhoirmle an bealach ar fad síos chun í a chur i bhfeidhm ar chealla eile.
=LEFT(B3,FIND("[",SUBSTITUTE(B3," ","[",LEN(B3)-LEN(SUBSTITUTE(B3," ",""))))-1)
Anois baintear gach focal i gcealla ar leith seachas na focail dheireanacha.
nótaí: San fhoirmle thuas, is é B3 an chill ina bhfuil na focail a bhainfidh tú amach seachas an ceann deireanach. Athraigh é le do thoil bunaithe ar do riachtanas.
Conas a oibríonn an fhoirmle seo?
=LEFT(B3,FIND("[",SUBSTITUTE(B3," ","[",LEN(B3)-LEN(SUBSTITUTE(B3," ",""))))-1)
1. SUBSTITUTE(B3," ","[",LEN(B3)-LEN(SUBSTITUTE(B3," ","")))
- LEN(B3): Ríomhann feidhm LEN fad iomlán an téacs "Excel handy addin" agus tugtar an toradh ar ais mar 17;
- LEN(SUBSTITUTE(B3," ","")): Cuireann an fheidhm SUBSTITUTE na spásanna go léir i "Excel handy addin" as oifig agus cuireann sé "Excelhandyaddin" ar ais, agus ansin ríomhann feidhm LEN fad iomlán an téacs "Excelhandyaddin". Is é an toradh deiridh ná 15;
- SUBSTITUTE(B3," ","[",17-15)): SUBSTITUTE (B3, "", "[", 2)) Cuirtear carachtar "[" in ionad na feidhme SUBSTITUTE i "Excel handy addin" agus cuireann sí an toradh ar ais mar "Excel handy [addin".
2. FIND("[","Excel handy[addin")
- Aimsíonn an fheidhm FIND suíomh an charachtair "[" i dtéad téacs "Excel handy [addin". Anseo tá an carachtar "[" sa 12ú háit sa téad téacs, mar sin tugann sé an toradh ar ais mar 12;
3. =LEFT(B3,12-1)
- Baineann an fheidhm LEFT 11 carachtar (12-1 = 11) as an taobh clé den sreangán téacs "Excel handy addin". Is é an toradh "Excel handy".
Feidhmeanna gaolmhara
Feidhm CEART Excel
Baineann feidhm Excel CEART líon sonrach carachtar ón taobh deas den tsreang téacs.
Feidhm Excel LEN
Filleann feidhm Excel LEN líon na gcarachtar i sreangán téacs.
Feidhm Excel FIND
Aimsíonn feidhm Excel FIND sreangán laistigh de shreang eile, agus filleann sí suíomh tosaigh na sreinge taobh istigh de cheann eile.
Feidhm LEFT Excel
Baineann feidhm Excel LEFT an líon áirithe carachtair as an taobh clé de shreang sholáthraithe.
Feidhm SUBSTITUTE Excel
Gabhann feidhm Excel SUBSTITUTE téacs nó carachtair eile in ionad téacs nó carachtair laistigh de shreang téacs.
Foirmlí gaolmhara
Sliocht Il-Línte as Cill
Má tá liosta de shreangáin téacs agat atá scartha le briseadh líne (a tharlaíonn trí eochracha Alt + Iontráil a bhrú agus tú ag dul isteach sa téacs), agus má theastaíonn uait na línte téacs seo a bhaint as ilchealla, déanfaidh an fhoirmle sa rang teagaisc seo duit a fabhar.
Sliocht an Líne Dheireanach den Téacs as Cill Illíne
Chun an líne dheiridh téacs a bhaint as sreangán téacs atá scartha le briseadh líne, is féidir le foirmle sa rang teagaisc seo cabhrú leat déileáil leis an tasc seo in Excel.
Sliocht Nú Focal as Teaghrán Téacs in Excel
Mínítear san alt seo conas foirmle a úsáid chun an naoú focal sonrach a bhaint as sreangán téacs i gcill in Excel.
Sliocht an dá fhocal dheireanacha as cill in Excel
Míníonn an teagaisc seo conas foirmle a úsáid chun an dá fhocal dheireanacha a bhaint as cill in Excel.
Sliocht Focal ag Tosú le Carachtar Sonrach In Excel
Soláthraíonn an rang teagaisc seo foirmle le céimeanna mionsonraithe chun cabhrú leat an focal a thosaíonn le carachtar ar leith a bhaint as sreangán téacs i gcill in Excel.
Na hUirlisí Táirgiúlachta Oifige is Fearr
Kutools for Excel - Cabhraíonn sé leat Seasamh Amach ón Slua
Tá os cionn 300 Gnéithe ag Kutools le haghaidh Excel, A chinntiú nach bhfuil uait ach cliceáil ar shiúl...
Cluaisín Oifige - Cumasaigh Léitheoireacht agus Eagarthóireacht Táblaithe i Microsoft Office (Excel san áireamh)
- Soicind le hathrú idir an iliomad doiciméad oscailte!
- Laghdaigh na céadta cad a tharlaíonn nuair luch duit gach lá, slán a fhágáil le lámh na luiche.
- Méadaíonn do tháirgiúlacht 50% agus tú ag féachaint ar agus ag eagarthóireacht iliomad doiciméad.
- Tugann sé Cluaisíní Éifeachtacha chuig Oifig (cuir Excel san áireamh), Just Like Chrome, Edge agus Firefox.
