Note: The other languages of the website are Google-translated. Back to English

Carachtair uimhriúla a stiall nó a bhaint as teaghráin téacs

Más mian leat na huimhreacha go léir a bhaint de liosta teaghráin téacs ach carachtair neamh-uimhriúla eile a choinneáil, b’fhéidir go bhfuil roinnt foirmlí in Excel is féidir leat fabhar a dhéanamh.


Stiall nó bain na huimhreacha go léir as teaghráin téacs in Excel

Gan ach uimhreacha a bhaint as teaghráin alfa-uimhriúla, is féidir le foirmle eagar casta a chomhcheanglaíonn feidhmeanna TEXTJOIN, MID, ROW, IF, ISERR, LEN agus INDIRECT cabhrú leat. (nótaí: Ní oibríonn an fhoirmle seo ach go maith in Excel 2019 agus in Oifig 365.) Is í an chomhréir chineálach:

=TEXTJOIN("",TRUE,IF(ISERR(MID(text,ROW(INDIRECT("1:"&LEN(text))),1)+0),MID(text,ROW(INDIRECT("1:"&LEN(text))),1),""))
  • text: an sreangán téacs nó an luach cille ar mhaith leat na huimhreacha go léir a bhaint di.

1. Déan an fhoirmle thíos a chóipeáil nó a iontráil i gcill bhán inar mian leat an toradh a aschur:

=TEXTJOIN("",TRUE,IF(ISERR(MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1)+0),MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1),""))

2. Ansin, brúigh Ctrl + Shift + Iontráil eochracha ag an am céanna chun an chéad toradh a fháil, féach an scáileán:

3. Agus ansin, roghnaigh an chill fhoirmle, tarraing an láimhseáil líonta síos go dtí na cealla a theastaíonn uait a úsáid, baineadh na huimhreacha go léir ó na teaghráin téacs, féach an scáileán:


Míniú ar an bhfoirmle:

ROW (INDIRECT ("1:" & LEN (A2))): Cuirfidh an fheidhm INDIRECT laistigh den fheidhm ROW liosta eagar ar ais arb é an fad atá i gcill A2 cosúil leis an gceann thíos, agus aithnítear an chuid seo mar an tús_num san fheidhm MID.
{1;2;3;4;5;6;7;8;9;10;11;12;13;14;15;16;17;18;19;20;21}

MID (A2, ROW (INDIRECT ("1:" & LEN (A2))), 1): Úsáidtear an fheidhm MID seo chun téacs a bhaint as cill A2 chun carachtar amháin a fháil, agus fillfidh sé eagar mar seo:
{"5"; "0"; "0"; ""; "K"; "u"; "t"; "o"; "o"; "l"; "s"; ""; "f" ; "o"; "r"; ""; "E"; "x"; "c"; "e"; "l"}

MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1)+0: Nuair a chuirtear 0 luach leis tar éis an tsraith seo a úsáid chun an téacs a chur i bhfeidhm ar uimhir, athrófar luach an téacs uimhriúil go huimhir, agus taispeánfar luachanna neamhuimhreacha mar luach earráide #VALUE mar seo:
{"5"; "0"; "0"; # LUACH !; # LUACH !; # LUACH !; # LUACH !; # LUACH !; # LUACH! !; # LUACH! !; # LUACH! ...}

IF(ISERR(MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1)+0),MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1),""): Úsáidtear feidhm IF chun a sheiceáil an luachanna earráide iad an eagar a chuirtear ar ais le feidhm MID nó nach ea. Más luach earráide é, ansin faigh an carachtar neamh-uimhriúil agus an dara feidhm MID á úsáid agat, ar shlí eile, taispeántar teaghráin fholamh mar seo:
{""; ""; ""; ""; "K"; "u"; "t"; "o"; "o"; "l"; "s"; ""; "f"; "o ";" r ";" ";" E ";" x ";" c ";" e ";" l "}

TEXTJOIN("",TRUE,IF(ISERR(MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1)+0),MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1),"")): Faoi dheireadh, nascfaidh feidhm TEXTJOIN leis na luachanna go léir agus tabharfaidh sí neamhaird ar an sreangán folamh chun an toradh a fháil.


Nótaí:

1. Agus carachtair uimhriúla á mbaint amach, b’fhéidir go bhfuil roinnt carachtair spáis bhreise fágtha, chun gach spás breise a bhaint, ba chóir duit an fhoirmle a fhilleadh ar fheidhm TRIM mar atá thíos:

=TRIM(TEXTJOIN("",TRUE,IF(ISERR(MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1)+0),MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1),"")))

2. Chun uimhreacha a bhaint as teaghráin téacs i leaganacha luatha Excel, cuir an fhoirmle seo a leanas i bhfeidhm:

=SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A2,1,""),2,""),3,""),4,""),5,""),6,""),7,""),8,""),9,""),0,"")


Feidhmeanna coibhneasta a úsáidtear:

  • TEXTJOIN:
  • Ceanglaíonn feidhm TEXTJOIN luachanna iolracha as a chéile, as colún nó as raon cealla le teimpléad sonrach.
  • MID:
  • Úsáidtear an fheidhm MID chun líon sonrach carachtar a aimsiú agus a chur ar ais ó lár na sreinge téacs tugtha.
  • ROW:
  • Filleann feidhm Excel ROW an tsraithuimhir tagartha.
  • INDIRECT:
  • Athraíonn feidhm Excel INDIRECT sreang téacs go tagairt bhailí.
  • LEN:
  • Filleann feidhm LEN líon na gcarachtar i sreangán téacs.
  • IF:
  • Déanann feidhm IF tástáil loighciúil shimplí a bhraitheann ar thoradh na comparáide, agus faightear luach amháin ar ais más toradh FÍOR é, nó luach eile más FALSE an toradh.
  • ISERR:
  • Úsáidtear feidhm ISERR chun TRUE a chur ar ais d’aon chineál earráide seachas an earráid # N / A.

Tuilleadh alt:

  • Bain Sosanna Líne ó Chealla in Excel
  • Soláthraíonn an teagaisc seo trí fhoirmle chun cabhrú leat briseadh líne (a tharlaíonn trí eochracha Alt + Iontráil i gcill) a bhrú ó chealla ar leith in Excel.
  • Stiallacha Nó Bain Carachtair Neamhuimhriúla as Teaghráin Téacs
  • Uaireanta, b’fhéidir go mbeidh ort na carachtair neamh-uimhriúla go léir a bhaint de na teaghráin téacs, agus gan na huimhreacha a choinneáil mar atá thíos an pictiúr a thaispeántar. Tabharfaidh an t-alt seo roinnt foirmlí isteach chun an tasc seo a réiteach in Excel.

Na hUirlisí Táirgiúlachta Oifige is Fearr

Kutools for Excel - Cabhraíonn sé leat Seasamh Amach ón Slua

Ar mhaith leat do chuid oibre laethúil a chríochnú go tapa agus go foirfe? Tugann Kutools le haghaidh Excel ardghnéithe cumhachtacha 300 (Comhcheangail leabhair oibre, suim de réir datha, inneachar cille scoilte, dáta a thiontú, agus mar sin de ...) agus sábháil 80% ama duit.

  • Deartha do 1500 cás oibre, cabhraíonn sé leat fadhbanna 80% Excel a réiteach.
  • Laghdaigh na mílte cad a tharlaíonn nuair méarchlár agus luch gach lá, faoiseamh a thabhairt do do shúile agus do lámha tuirseach.
  • Bí i do shaineolaí Excel i gceann 3 nóiméad. Ní gá cuimhneamh a thuilleadh ar aon fhoirmlí pianmhara agus cóid VBA.
  • Triail saor in aisce gan teorainn 30 lá. Ráthaíocht ar ais airgid 60 lá. Uasghrádú agus tacaíocht saor in aisce ar feadh 2 bhliain.
Ribín Excel (le Kutools le haghaidh Excel suiteáilte)

Cluaisín Oifige - Cumasaigh Léitheoireacht agus Eagarthóireacht Táblaithe i Microsoft Office (Excel san áireamh)

  • Soicind le hathrú idir an iliomad doiciméad oscailte!
  • Laghdaigh na céadta cad a tharlaíonn nuair luch duit gach lá, slán a fhágáil le lámh na luiche.
  • Méadaíonn do tháirgiúlacht 50% agus tú ag féachaint ar agus ag eagarthóireacht iliomad doiciméad.
  • Tugann Cluaisíní Éifeachtacha chuig an Oifig (Excel san áireamh), Díreach Cosúil le Chrome, Firefox, agus New Internet Explorer.
Urchar Scáileáin de Excel (le Office Tab suiteáilte)
Sórtáil tuairimí de réir
Comments (0)
Níl rátálacha ar bith fós. Bí ar an gcéad duine a rátáil!
Níl aon tráchtanna curtha suas anseo go fóill
Fág do chuid tuairimí
Ag postáil mar Aoi
×
Ráta an post seo:
0   Carachtair
Suímh Molta

Lean orainn

Cóipcheart © 2009 - www.extendoffice.com. | Gach ceart ar cosaint. Cumhachtaithe ag ExtendOffice. | léarscáil an tSuímh
Is trádmharcanna nó trádmharcanna cláraithe de chuid Microsoft Corporation sna Stáit Aontaithe agus / nó i dtíortha eile iad lógó Office agus Office.
Cosanta ag Sectigo SSL